*April 10, 2006
*Doc. ID: 75142, S-60544, Rev. B
*File Name: SUD45P03-10_PS.txt and SUD45P03-10_PS.lib
*This document is intended as a SPICE modeling guideline and does not
*constitute a commercial product data sheet.  Designers should refer to the
*appropriate data sheet of the same number for guaranteed specification
*limits.
.SUBCKT sud45p03 4 1 2
M1  3 1 2 2 PMOS W=3807292u L=0.5u 
M2  2 1 2 4 NMOS W=3807292u L=0.9u
R1  4 3     RTEMP 25E-4
CGS 1 2     4400E-12
DBD 4 2     DBD
**************************************************************************
.MODEL  PMOS       PMOS (  LEVEL  = 3               TOX    = 5E-8
+ RS     = 36E-4           RD     = 0               NSUB   = 5E16   
+ kp     = 0.66E-5         UO     = 400             
+ VMAX   = 0               XJ     = 0.5E-6          KAPPA  = 0.1E-2
+ ETA    = 1E-4            TPG    = -1  
+ IS     = 0               LD     = 0                             
+ CGSO   = 0               CGDO   = 0               CGBO   = 0 
+ NFS    = 0.8E12          DELTA  = 0.1)
*************************************************************************
.MODEL  NMOS       NMOS (  LEVEL  = 3               TOX    = 5E-8
+NSUB    = 7.9E16          NFS    = 10E11           TPG    = -1)   
*************************************************************************
.MODEL DBD D (CJO=1200E-12  VJ=0.38    M=0.22
+RS=0.1 FC=0.5 IS=1E-8 TT=2.4E-8 N=1 BV=40)
*************************************************************************
.MODEL RTEMP RES (TC1=10E-3   TC2=11E-6)
*************************************************************************
.ENDS