*November 27, 2006
*Doc. ID: 75155, S-62314, Rev. B
*This document is intended as a SPICE modeling guideline and does not
*constitute a commercial product data sheet.  Designers should refer to the
*appropriate data sheet of the same number for guaranteed specification
*limits.
.SUBCKT SUM110N04-02L D G S
M1  3  G  S S NMOS W=13621800u L=0.50u  
M2  S  G  S D PMOS W=13621800u L=0.85u 
R1  D  3      RTEMP 0.9E-3
CGS G  S      3800E-12
DBD S  D      DBD
**************************************************************** 
.MODEL  NMOS       NMOS (  LEVEL  = 3           TOX    = 7E-8
+ RS     = 0.65E-3         RD     = 0           NSUB   = 1.55E17   
+ KP     = 2.1E-5          UO     = 650             
+ VMAX   = 0               XJ     = 5E-7        KAPPA  = 26E-2
+ ETA    = 1E-4            TPG    = 1  
+ IS     = 0               LD     = 0                             
+ CGSO   = 0               CGDO   = 0           CGBO   = 0 
+ TLEV   = 1               BEX    = -1.5        TCV    = 4.8E-3
+ NFS    = 0.8E12          DELTA  = 0.1)
**************************************************************** 
.MODEL  PMOS       PMOS (  LEVEL  = 3           TOX    = 7E-8
+NSUB    = 1.8E16          IS	  = 0		TPG    = -1)           
**************************************************************** 
.MODEL DBD D (CJO=2200E-12 VJ=0.38 M=0.35 EG=1.17
+FC=0.1 TT=4E-8 TREF=25 BV=40.5
+IS=2.057e-09 RS=1.542e-03 N=1.235
+XTI=2.073 TRS=3.136e-03)
**************************************************************** 
.MODEL RTEMP R (TC1=8E-3 TC2=5.5E-6)
**************************************************************** 
.ENDS