*Feb. 7, 2005
*Doc. ID: 75160, S-50151, Rev. B
*File Name: Si1303DL_PS.txt and Si1303DL_PS.lib
.SUBCKT Si1303DL 4 1 2
M1  3 1 2 2 PMOS W=111936u  L=0.50u 
M2  2 1 2 4 NMOS W=111936u  L=0.80u   
R1  4 3     RTEMP 65E-3
CGS 1 2     90E-12
DBD 4 2     DBD
**************************************************************************
.MODEL  PMOS       PMOS (  LEVEL  = 3               TOX    = 3E-8
+ RS     = 235E-3          RD     = 0               NSUB   = 1.6E16   
+ KP     = 1.9E-5          UO     = 400             
+ VMAX   = 0               XJ     = 5E-7            KAPPA  = 3E-3
+ ETA    = 1E-4            TPG    = -1  
+ IS     = 0               LD     = 0                
+ CGSO   = 0               CGDO   = 0               CGBO   = 0 
+ NFS    = 0.8E12          DELTA  = 0.1)
*************************************************************************
.MODEL  NMOS       NMOS (  LEVEL  = 3               TOX    = 3E-8
+NSUB    = 4.5E16           NFS   = 10E11           TPG    = -1)   
*************************************************************************
.MODEL DBD D (CJO=60E-12 VJ=0.38    M=0.30
+RS=0.1 FC=0.5 IS=1E-12 TT=5E-8 N=1 BV=20.2)
*************************************************************************
.MODEL RTEMP RES (TC1=10E-3   TC2=5.5E-6)
*************************************************************************
.ENDS