*Oct 31, 2005
*Doc. ID: 75176, S-52291, Rev. D
.SUBCKT Si1410EDH 4 1 2
M1  3 5 2 2 NMOS W=334058u L=0.50u
M2  2 5 2 4 PMOS W=334058u L=0.60u
R1  4 3     RTEMP 35E-3
CGS 5 2     290E-12
DBD 2 4     DBD
xesd 1 5 2  Si1410EDH_esd
************************************************************  
.MODEL  NMOS         NMOS (LEVEL  = 3        TOX    = 1.7E-8
+ RS     = 10E-3           RD     = 0        NSUB   = 1.85E17   
+ KP     = 4.2E-5          UO     = 650             
+ VMAX   = 0               XJ     = 5E-7     KAPPA  = 10E-2
+ ETA    = 1E-4            TPG    = 1  
+ IS     = 0               LD     = 0                             
+ CGSO   = 0               CGDO   = 0        CGBO   = 0 
+ TLEV   = 1               BEX    = -1.5     TCV    = 1.7E-3
+ NFS    = 0.8E12          DELTA  = 0.1)
************************************************************  
.MODEL  PMOS         PMOS (LEVEL  = 3        TOX    = 1.7E-8
+NSUB    = 5E16            TPG    = -1)   
************************************************************  
.MODEL DBD D (CJO=95E-12 VJ=0.38 M=0.30
+RS=0.05 FC=0.1 IS=1E-12 TT=4E-8 N=1 BV=20.2)
************************************************************ 
.MODEL RTEMP R (TC1=4.8E-3   TC2=5.5E-6)
************************************************************  
.ENDS Si1410EDH
.subckt Si1410EDH_esd 1 5 2
rd7 1 9 400 
d7 9 2 dleak M=1
.MODEL dleak d (IS=3e-9 XTI=410 EG=1.17 TREF=25 TCV=0 N=42 BV=6.4) 
rd3 1 10 105 TC=-0.002
d3 11 10 dout M=1.422
d4 11 12 dout M=1.422
d5 13 12 dout M=1.78
d6 13 2 dout M=1.78
.MODEL dout D (IS=1E-10 XTI=-35 EG=1.17 TREF=25 TCV=6.48e-3 N=2.5 BV=6.11)
rpoly 1 5 1.45K TC=0.001
rd8 5 14 1 
d8 15 14 din M=1
d9 15 2  din M=1
.MODEL din D (IS=3E-10 XTI=-20 EG=1.17 TREF=25 TCV=-5e-4 N=1.3 BV=6.28)
.ends Si1410EDH_esd