*July 27, 2005
*Doc. ID: 75179, S-51305, Rev. C
.SUBCKT Si1413EDH 4 1 2
M1   3 5 2 2 PMOS W=334058u L=0.50u
M2   2 5 2 4 NMOS W=334058u L=0.90u
R1   4 3     RTEMP 40E-3
CGS  5 2     250E-12
DBD  4 2     DBD
XESD 1 5 2   Si1413EDH_esd
*****************************************************************
.MODEL  PMOS        PMOS ( LEVEL  = 3             TOX    = 1.7E-8
+ RS     = 34E-3           RD     = 0             NSUB   = 3.4E15   
+ KP     = 1.8E-5          UO     = 400             
+ VMAX   = 0               XJ     = 5E-7          KAPPA  = 5E-4
+ ETA    = 1E-4            TPG    = -1  
+ IS     = 0               LD     = 0                        
+ CGSO   = 0               CGDO   = 0             CGBO   = 0 
+ TLEV   = 1               BEX    = -1.5          TCV    = 1.8E-3
+ NFS    = 0.8E12	   DELTA  = 0.1)
*****************************************************************
.MODEL  NMOS        NMOS ( LEVEL  = 3             TOX    = 1.7E-8
+NSUB    = 4E16            TPG    = 1)   
*****************************************************************
.MODEL DBD D (CJO=100E-12 VJ=0.38 M=0.33
+RS=0.1 FC=0.5 IS=1E-12 TT=6.7E-8 N=1 BV=20.2)
*****************************************************************
.MODEL RTEMP R (TC1=6.5E-3  TC2=5.5E-6)
*****************************************************************
.ENDS Si1413EDH
.subckt Si1413EDH_esd 1 5 2
rd7 1 9 40k TC=0.02
d7 9 2 dleak M=1
.MODEL dleak d (IS=1.2e-8 XTI=410 EG=1.17 TREF=25 TCV=0 N=50 BV=6.4) 
rd3 1 10 125 TC=-0.002
d3 11 10 dout M=1.422
d4 11 12 dout M=1.422
d5 13 12 dout M=1.78
d6 13 2 dout M=1.78
.MODEL dout D (IS=5.1E-9 XTI=-35 EG=1.17 TREF=25 TCV=4.25e-3 N=2.05 BV=6.39)
rpoly 1 5 4K TC=0.001
rd8 5 14 1 
d8 15 14 din M=1
d9 15 2 din M=1
.MODEL din D (IS=5.1E-9 XTI=-20 EG=1.17 TREF=25 TCV=0 N=2.05 BV=6.43)
.ends Si1413EDH_esd