*Feb. 28, 2005
*Doc. ID: 75190, S-50232, Rev. B
*File Name: Si1903DL_PS.txt and Si1903DL_PS.lib
.SUBCKT Si1903DL 4 1 2
M1  3 1 2 2 PMOS W=40408u L=0.70u
M2  2 1 2 4 NMOS W=40408u L=0.70u  
R1  4 3     RTEMP 240E-3
CGS 1 2     30E-12
DBD 4 2     DBD
**************************************************************************
.MODEL  PMOS       PMOS (  LEVEL  = 3               TOX    = 3E-8
+ RS     = 330E-3          RD     = 0               NSUB   = 0.94E16   
+ KP     = 2E-5            UO     = 400             
+ VMAX   = 0               XJ     = 5E-7            KAPPA  = 40E-3
+ ETA    = 1E-4            TPG    = -1  
+ IS     = 0               LD     = 0                
+ CGSO   = 0               CGDO   = 0               CGBO   = 0 
+ NFS    = 0.8E12          DELTA  = 0.1)
*************************************************************************
.MODEL  NMOS       NMOS (  LEVEL  = 3               TOX    = 3E-8
+NSUB    = 4E16            NFS    = 10E11           TPG    = -1)   
*************************************************************************
.MODEL DBD D (CJO=28E-12 VJ=0.38 M=0.3
+RS=4 FC=0.5 IS=0.2E-9 TT=5E-8 N=1 BV=30.2)
*************************************************************************
.MODEL RTEMP RES (TC1=8E-3 TC2=5.5E-6)
*************************************************************************
.ENDS