*February 12, 2007
*Doc. ID: 75235, S-70286, Rev. C
*File Name: Si2309DS_PS.txt and Si2309DS_PS.lib
*This document is intended as a SPICE modeling guideline and does not
*constitute a commercial product data sheet.  Designers should refer to the
*appropriate data sheet of the same number for guaranteed specification
*limits.
.SUBCKT Si2309DS 4 1 2
M1  3 1 2 2 PMOS W=181400u L=0.30u 
M2  2 1 2 4 NMOS W=181400u L=1.50u
R1  4 3     RTEMP 150E-3
CGS 1 2     240E-12
DBD 4 2     DBD
*****************************************************************
.MODEL  PMOS       PMOS (  LEVEL  = 3             TOX    = 5E-8
+ RS     = 127E-3          RD     = 0             NSUB   = 0.87E17   
+ kp     = 0.69E-5         UO     = 400             
+ VMAX   = 0               XJ     = 0.5E-6        KAPPA  = 24E-3
+ ETA    = 1E-4            TPG    = -1  
+ IS     = 0               LD     = 0                        
+ CGSO   = 0               CGDO   = 0             CGBO   = 0 
+ NFS    = 0.8E12          DELTA  = 0.1)
*****************************************************************
.MODEL  NMOS       NMOS (  LEVEL  = 3             TOX    = 5E-8
+NSUB    = 47E15           TPG    = 1)   
*****************************************************************
.MODEL DBD D (CJO=100E-12 VJ=0.38 M=0.38
+RS=0.1 FC=0.5 IS=1E-12 TT=3.6E-8 N=1 BV=62)
*****************************************************************
.MODEL RTEMP RES (TC1=9.5E-3 TC2=5.5E-6)
*****************************************************************
.ENDS