*March 21, 2005
*Doc. ID: 75277, S-50383, Rev. B
*File Name: Si3455ADV_ps.txt and Si3455ADV_ps.lib
.SUBCKT SI3455ADV 4 1 2
M1  3 1 2 2 PMOS W=498114u L=0.50u 
M2  2 1 2 4 NMOS W=498114u L=1.01u
R1  4 3 RTEMP 22E-3
CGS 1 2 265E-12
DBD 4 2 DBD
*****************************************************************
.MODEL  PMOS       PMOS (  LEVEL  = 3             TOX    = 5E-8
+ RS     = 43E-3           RD     = 0             NSUB   = 0.78E17   
+ kp     = 1E-5            UO     = 400             
+ VMAX   = 0               XJ     = 5E-7          KAPPA  = 120E-3
+ ETA    = 1E-4            TPG    = -1  
+ IS     = 0               LD     = 0                        
+ CGSO   = 0               CGDO   = 0             CGBO   = 0 
+ NFS    = 0.8E12          DELTA  = 0.1)
*****************************************************************
.MODEL  NMOS       NMOS (  LEVEL  = 3             TOX    = 5E-8
+NSUB    = 23E15           TPG    = 1)   
*****************************************************************
.MODEL DBD D (CJO=200E-12 VJ=0.38    M=0.33
+RS=0.1 FC=0.5 IS=1E-11 TT=4.55E-8 N=1 BV=35)
*****************************************************************
.MODEL RTEMP RES (TC1=12E-3   TC2=5.5E-6)
*****************************************************************
.ENDS