*Jan 23, 2006
*Doc. ID: 75340, S-60073, Rev. B
*File Name: Si4466DY_PS.txt and Si4466DY_PS.lib
.SUBCKT si4466dy 4 1 2   
M1  3 1 2 2 NMOS W=7286742u L=0.5u 
M2  2 1 2 4 PMOS W=7286742u L=0.6u
R1  4 3     RTEMP 48E-4
CGS 1 2     2790E-12
DBD 2 4     DBD
**************************************************************************
.MODEL  NMOS       NMOS  (LEVEL  = 3               TOX    = 3E-8
+ RS     = 7.3E-4         RD     = 0               NSUB   = 14.5E16  
+ kp     = 1.85E-5        UO     = 400             
+ VMAX   = 0              XJ     = 0.5E-6          KAPPA  = 2.29E-2
+ ETA    = 1E-4           TPG    = 1  
+ IS     = 0              LD     = 0               WD     = 0               
+ CGSO   = 0              CGDO   = 0               CGBO   = 0 
+ NFS    = 0.8E12         DELTA  = 0.1)
*************************************************************************
.MODEL  PMOS       PMOS (LEVEL   = 3               TOX    = 5E-8
+NSUB    = 1.2E16         NFS    = 10E11           TPG    = -1)   
*************************************************************************
.MODEL DBD D (CJO=1870E-12 VJ=0.38    M=0.32
+RS=0.1 FC=0.5 IS=1E-10 TT=2.7E-8 N=1 BV=40)
*************************************************************************
.MODEL RTEMP RES (TC1=3.3E-3   TC2=5.5E-6)
*************************************************************************
.ENDS
 
*This document is intended as a SPICE modeling guideline and does not
*constitute a commercial product data sheet.  Designers should refer to the
*appropriate data sheet of the same number for guaranteed specification
*limits.