*February 20, 2006
*Doc. ID: 75397,S-60245, Rev. B
*File Name: Si4840DY_PS.txt and Si4840DY_PS.lib
*This document is intended as a SPICE modeling guideline and does not
*constitute a commercial product data sheet.  Designers should refer to the
*appropriate data sheet of the same number for guaranteed specification
*limits.
.SUBCKT SI4840DY 4 1 2
M1  3 1 2 2 NMOS W=3292404u L=0.50u 
M2  2 1 2 4 PMOS W=3292404u L=0.60u
R1  4 3     RTEMP 35E-4
CGS 1 2     870E-12
DBD 2 4     DBD
**************************************************************************
.MODEL  NMOS       NMOS (  LEVEL  = 3               TOX    = 7E-8
+ RS     = 19E-4           RD     = 0               NSUB   = 0.9E17   
+ kp     = 1.65E-5         UO     = 650             
+ VMAX   = 0               XJ     = 5E-7            KAPPA  = 35E-2
+ ETA    = 1E-4            TPG    = 1  
+ IS     = 0               LD     = 0                             
+ CGSO   = 0               CGDO   = 0               CGBO   = 0 
+ NFS    = 0.8E12          DELTA  = 0.1)
*************************************************************************
.MODEL  PMOS       PMOS (LEVEL    = 3               TOX    = 7E-8
+NSUB    = 1.8E16          TPG    = -1)   
*************************************************************************
.MODEL DBD D (CJO=1200e-12 VJ=.38    M=0.38 
+FC=0.1 IS=1E-12 TT=9.3E-8 N=1 BV=40.5)
*************************************************************************
.MODEL RTEMP RES (TC1=6E-3   TC2=5.5E-6)
*************************************************************************
.ENDS