*Oct 3, 2005
*Doc. ID: 75496, S-51983, Rev. B
*File Name: Si5463EDC_PS.txt and Si5463EDC_PS.lib
.SUBCKT Si5463EDC 4 1 2
M1   3 5 2 2 PMOS W=526908u L=0.5u
M2   2 5 2 4 NMOS W=526908u L=1.0u
R1   4 3     RTEMP 10E-3
CGS  5 2     600E-12
DBD  4 2     DBD
xesd 1 5 2   Si5463EDC_esd
*****************************************************************
.MODEL  PMOS       PMOS (  LEVEL  = 3             TOX    = 1.7E-8
+ RS     = 25E-3           RD     = 0             NSUB   = 6E15   
+ KP     = 1.8E-5          UO     = 400             
+ VMAX   = 0               XJ     = 5E-7          KAPPA  = 9E-4
+ ETA    = 1E-4            TPG    = -1  
+ IS     = 0               LD     = 0                        
+ CGSO   = 0               CGDO   = 0             CGBO   = 0 
+ NFS    = 0.8E12	   DELTA  = 0.1)
*****************************************************************
.MODEL  NMOS       NMOS (  LEVEL  = 3             TOX    = 1.7E-8
+NSUB    = 60E15           TPG    = 1)   
*****************************************************************
.MODEL DBD D (CJO=450E-12 VJ=0.38 M=0.33
+RS=0.05 FC=0.5 IS=1E-12 TT=6.7E-8 N=1 BV=20.2)
*****************************************************************
.MODEL RTEMP RES (TC1=11E-3 TC2=5.5E-6)
*****************************************************************
.ENDS Si5463EDC
.subckt Si5463EDC_esd 1 5 2
rleak 2 9 500000 TC=-4e-3
dleak 9 1 dleak  
.MODEL dleak d (IS=1.666e-9 XTI=317.5 EG=1.17 T_MEASURED=25 TBV1=0 N=30.11 BV=50) 
rout 2 10 94.95 TC=-2.044e-3
dout1 10 11 dout  
dout2 11 12 dout  
dout3 1 12 dout  
.MODEL dout D (IS=1e-12 XTI=-16.77 EG=1.17 T_MEASURED=25 TBV1=-5.117e-4 N=1.779 BV=11.86)
rpoly 1 5 6.8k TC=8.867e-5
rd8 2 20 31.95 TC=3.589e-3
din1 20 21 din  
din2 5 21 din  
.MODEL din D (IS=1e-12 XTI=-15.74 EG=1.17 T_MEASURED=25 TBV1=-4.981e-4 N=2.202 BV=5.633)
.ends Si5463EDC_esd