*Jan 23, 2006
*Doc. ID: 75503, S-60072, Rev. B
.SUBCKT Si5902DC 4 1 2
M1  3 1 2 2 NMOS W=194914u L=0.5u 
M2  2 1 2 4 PMOS W=194914u L=1.0u 
R1  4 3     RTEMP 28E-3
CGS 1 2     185E-12
DBD 2 4     DBD
**************************************************************************
.MODEL  NMOS       NMOS  (LEVEL  = 3               TOX    = 5E-8
+ RS     = 32E-3          RD     = 0               NSUB   = 1.7E17  
+ kp     = 3.03E-5        UO     = 650             
+ VMAX   = 0              XJ     = 0.5E-6          KAPPA  = 3E-1
+ ETA    = 1.0E-4         TPG    = 1  
+ IS     = 0              LD     = 0                           
+ CGSO   = 0              CGDO   = 0               CGBO   = 0 
+ TLEV   = 1              BEX    = -1.4            TCV    = 3.9E-3
+ NFS    = 0.8E12         DELTA  = 0.1)
*************************************************************************
.MODEL  PMOS       PMOS (LEVEL   = 3               TOX    = 5E-8
+NSUB    = 2.5E16         TPG    = -1)   
*************************************************************************
.MODEL DBD D (CJO=110E-12 VJ=0.38 M=0.32
+RS=1 FC=0.5 IS=1E-12 TT=14.5E-8 N=1 BV=40)
*************************************************************************
.MODEL RTEMP R (TC1=8.5E-3   TC2=5.5E-6)
*************************************************************************
.ENDS
 
*This document is intended as a SPICE modeling guideline and does not
*constitute a commercial product data sheet.  Designers should refer to the
*appropriate data sheet of the same number for guaranteed specification
*limits.