*January 21, 2008
*Doc. ID: 75605, S-80012, Rev. C
*This document is intended as a SPICE modeling guideline and does not
*constitute a commercial product data sheet.  Designers should refer to the
*appropriate data sheet of the same number for guaranteed specification
*limits.
.SUBCKT SI7904DN 4 1 2
M1  3 1 2 2 NMOS W=698798u L=0.50u 
M2  2 1 2 4 PMOS W=698798u L=0.45u
R1  4 3     RTEMP 145E-4
CGS 1 2     530E-12
DBD 2 4     DBD
**************************************************************************
.MODEL  NMOS       NMOS (  LEVEL  = 3               TOX    = 1.7E-8
+ RS     = 29E-4           RD     = 0               NSUB   = 1.85E17   
+ KP     = 3.5E-5          UO     = 650             
+ VMAX   = 0               XJ     = 5E-7            KAPPA  = 2E-2
+ ETA    = 1E-4            TPG    = 1  
+ IS     = 0               LD     = 0                             
+ CGSO   = 0               CGDO   = 0               CGBO   = 0 
+ TLEV   = 1               BEX    = -1.5            TCV    = 2.1E-3
+ NFS    = 0.8E12          DELTA  = 0.1)
*************************************************************************
.MODEL  PMOS       PMOS (LEVEL    = 3               TOX    = 1.7E-8
+NSUB    = 7E16            TPG    = -1)   
*************************************************************************
.MODEL DBD D (CJO=280E-12 VJ=.38  M=0.30
+FC=0.1 IS=1E-12 TT=5E-8 N=1 BV=21)
*************************************************************************
.MODEL RTEMP R (TC1=5E-3 TC2=5.5E-6)
*************************************************************************
.ENDS