*July 30, 2007
*Doc. ID: 75797, S-71527, Rev. B
*This document is intended as a SPICE modeling guideline and does not
*constitute a commercial product data sheet.  Designers should refer to the
*appropriate data sheet of the same number for guaranteed specification
*limits.
.SUBCKT SUP18N15-95 4 1 2
M1  3 1 2 2 NMOS W=1995278u L=0.50u 
M2  2 1 2 4 PMOS W=1995278u L=0.90u
R1  4 3     RTEMP 57E-3
CGS 1 2     500E-12
DBD 2 4     DBD
**************************************************************************
.MODEL  NMOS       NMOS (  LEVEL  = 3               TOX    = 10E-8
+ RS     = 7E-3            RD     = 0               NSUB   = 1.05E17   
+ KP     = 8E-6            UO     = 650             
+ VMAX   = 0               XJ     = 5E-7            KAPPA  = 13E-2
+ ETA    = 1E-4            TPG    = 1  
+ IS     = 0               LD     = 0                             
+ CGSO   = 0               CGDO   = 0               CGBO   = 0 
+ TLEV   = 1               BEX    = -1.5            TCV    = 7.7E-3
+ NFS    = 0.8E12          DELTA  = 0.1)
*************************************************************************
.MODEL  PMOS       PMOS (LEVEL    = 3               TOX    = 10E-8
+NSUB    = 5E15            TPG    = -1)           
 *********************************************************************
.MODEL DBD D (CJO=270E-12 VJ=.38  M=0.39
+RS=0.1 FC=0.1 IS=1E-12 TT=5E-8 N=1 BV=100.2)
*************************************************************************
.MODEL RTEMP R (TC1=7E-3 TC2=5.5E-6)
*************************************************************************
.ENDS