*Feb. 7, 2005
*Doc. ID: 75817, S-50151, Rev. B
*File Name: Si1406DH_PS.txt and Si1406DH_PS.lib
.SUBCKT Si1406DH 4 1 2
M1  3 1 2 2 NMOS W=334014u L=0.50u
M2  2 1 2 4 PMOS W=334014u L=0.50u
R1  4 3     RTEMP  36E-3
CGS 1 2     230E-12
DBD 2 4     DBD
**************************************************************************
.MODEL  NMOS       NMOS  (LEVEL  = 3               TOX    = 1.7E-8
+ RS     = 10E-3          RD     = 0               NSUB   = 2.56E17  
+ KP     = 6E-5           UO     = 650             
+ VMAX   = 0              XJ     = 5E-7            KAPPA  = 5E-2
+ ETA    = 1E-4           TPG    = 1  
+ IS     = 0              LD     = 0                           
+ CGSO   = 0              CGDO   = 0               CGBO   = 0 
+ NFS    = 0.8E12         DELTA  = 0.1)
*************************************************************************
.MODEL  PMOS       PMOS (LEVEL   = 3               TOX    = 1.7E-8
+NSUB    = 8E16           TPG    = -1)   
*************************************************************************
.MODEL DBD D (CJO=130E-12 VJ=0.38 M=0.30
+RS=0.03 FC=0.5 IS=1E-12 TT=9E-8 N=1 BV=20.2)
*************************************************************************
.MODEL RTEMP RES (TC1=4.5E-3 TC2=5.5E-6)
*************************************************************************
.ENDS