*Nov 21, 2005
*Doc. ID: 75862, S-52398, Rev. B
*File Name: Si8401DB_PS.txt and Si8401DB_PS.lib
.SUBCKT Si8401DB 4 1 2
M1  3 1 2 2 PMOS W=825394u L=0.50u
M2  2 1 2 4 NMOS W=825394u L=0.85u
R1  4 3     RTEMP 19E-3
CGS 1 2     500E-12
DBD 4 2     DBD
*****************************************************************
.MODEL  PMOS       PMOS (  LEVEL  = 3             TOX    = 3E-8
+ RS     = 21E-3           RD     = 0             NSUB   = 0.96E16   
+ KP     = 1.1E-5          UO     = 400             
+ VMAX   = 0               XJ     = 5E-7          KAPPA  = 1.6E-2
+ ETA    = 1E-4            TPG    = -1  
+ IS     = 0               LD     = 0                        
+ CGSO   = 0               CGDO   = 0             CGBO   = 0 
+ NFS    = 0.8E12	   DELTA  = 0.1)
*****************************************************************
.MODEL  NMOS       NMOS (  LEVEL  = 3             TOX    = 3E-8
+NSUB    =.5E17            TPG    = 1)   
*****************************************************************
.MODEL DBD D (CJO=400E-12 VJ=0.38 M=0.32
+RS=0.01 FC=0.5 IS=1E-12 TT=6E-8 N=1 BV=20.2)
*****************************************************************
.MODEL RTEMP RES (TC1=7.5E-3  TC2=5.5E-6)
*****************************************************************
.ENDS