*Feb 20, 2006
*Doc. ID: 75868, S-60245, Rev. B
*This document is intended as a SPICE modeling guideline and does not
*constitute a commercial product data sheet.  Designers should refer to the
*appropriate data sheet of the same number for guaranteed specification
*limits.
*File Name: Si4864DY_PS.txt and Si4864DY_PS.lib
.SUBCKT Si4864DY 4 1 2
M1  3 1 2 2 NMOS W=4641966u L=0.50u
M2  2 1 2 4 PMOS W=4641966u L=0.30u
R1  4 3     RTEMP 0.17E-3
CGS 1 2     1800E-12
DBD 2 4     DBD
************************************************************  
.MODEL  NMOS         NMOS (LEVEL  = 3        TOX    = 1.7E-8
+ RS     = 1.9E-3          RD     = 0        NSUB   = 4.3E17  
+ KP     = 6.8E-5          UO     = 650             
+ VMAX   = 0               XJ     = 5E-7     KAPPA  = 10E-1
+ ETA    = 1E-4            TPG    = 1  
+ IS     = 0               LD     = 0                             
+ CGSO   = 0               CGDO   = 0        CGBO   = 0 
+ NFS    = 0.8E12          DELTA  = 0.1)
************************************************************  
.MODEL  PMOS         PMOS (LEVEL  = 3        TOX    = 1.7E-8
+NSUB    = 1E17            TPG    = -1)   
************************************************************  
.MODEL DBD D (CJO=1650E-12 VJ=0.38  M=0.2
+RS=0.01 FC=0.1 IS=1E-12 TT=5E-8 N=1 BV=20.2)
************************************************************ 
.MODEL RTEMP RES (TC1=8E-3  TC2=5.5E-6)
************************************************************  
.ENDS