*Jan 23, 2006
*Doc. ID: 75883, S-60073, Rev. B
*File Name: Si4953ADY_PS.txt and Si4953ADY_PS.lib
.SUBCKT Si4953ADY 4 1 2
M1  3 1 2 2 PMOS W=990224u L=0.50u
M2  2 1 2 4 NMOS W=990224u L=0.60u
R1  4 3     RTEMP 15E-3
CGS 1 2     500E-12
DBD 4 2     DBD
*****************************************************************
.MODEL  PMOS       PMOS (  LEVEL  = 3             TOX    = 5E-8
+ RS     = 23E-3           RD     = 0             NSUB   = 8.2E16   
+ KP     = 0.9E-5          UO     = 400             
+ VMAX   = 0               XJ     = 5E-7          KAPPA  = 25E-2
+ ETA    = 1E-4            TPG    = -1  
+ IS     = 0               LD     = 0                        
+ CGSO   = 0               CGDO   = 0             CGBO   = 0 
+ NFS    = 0.8E12	   DELTA  = 0.1)
*****************************************************************
.MODEL  NMOS       NMOS (  LEVEL  = 3             TOX    = 5E-8
+NSUB    = 6.2E16          TPG    = 1)   
*****************************************************************
.MODEL DBD D (CJO=380E-12 VJ=0.38 M=0.38
+RS=0.1 FC=0.5 IS=1E-12 TT=6E-8 N=1 BV=30.2)
*****************************************************************
.MODEL RTEMP RES (TC1=10E-3 TC2=5.5E-6)
*****************************************************************
.ENDS
 
*This document is intended as a SPICE modeling guideline and does not
*constitute a commercial product data sheet.  Designers should refer to the
*appropriate data sheet of the same number for guaranteed specification
*limits.