*Feb 13, 2006
*Doc. ID: 75916, S-60147, Rev. B
*File Name: Si6928DQ_PS.txt and Si6928DQ_PS.lib
*This document is intended as a SPICE modeling guideline and does not
*constitute a commercial product data sheet.  Designers should refer to the
*appropriate data sheet of the same number for guaranteed specification
*limits.
.SUBCKT Si6928DQ 4 1 2
M1  3 1 2 2 NMOS W=828290u L=0.5u 
M2  2 1 2 4 PMOS W=828290u L=0.7u  
R1  4 3     RTEMP 150E-4
CGS 1 2     925E-12
DBD 2 4     DBD
**************************************************************
.MODEL  NMOS       NMOS  (LEVEL  = 3          TOX    = 5E-8
+ RS     = 70E-4          RD     = 0          NSUB   = 1.81E17  
+ kp     = 2.2E-5         UO     = 650             
+ VMAX   = 0              XJ     = 0.5E-6     KAPPA  = 10E-3
+ ETA    = 1E-4           TPG    = 1  
+ IS     = 0              LD     = 0                           
+ CGSO   = 0              CGDO   = 0          CGBO   = 0 
+ NFS    = 0.8E12         DELTA  = 0.1)
**************************************************************
.MODEL  PMOS       PMOS (LEVEL   = 3          TOX    = 5E-8
+NSUB    = 1E16           TPG    = -1)   
**************************************************************
.MODEL DBD D (CJO=500E-12     VJ=0.38    M=0.3
+RS=0.1 FC=0.5 IS=1E-11 TT=3.9E-8 N=1 BV=40)
**************************************************************
.MODEL RTEMP RES (TC1=6E-3   TC2=5.5E-6)
**************************************************************
.ENDS