*Feb 7, 2005
*Doc. ID: 75973, S-50151, Rev. B
*File Name: Si1417EDH_ps.txt and Si1417EDH_ps.lib
.SUBCKT Si1417EDH 4 1 2
M1   3 5 2 2 PMOS W=334058u L=0.50u
M2   2 5 2 4 NMOS W=334058u L=0.60u
R1   4 3     RTEMP 20E-3
CGS  5 2     300E-12
DBD  4 2     DBD
XESD 1 5 2   Si1417EDH_ESD
*****************************************************************
.MODEL  PMOS        PMOS ( LEVEL  = 3             TOX    = 1.7E-8
+ RS     = 12E-3           RD     = 0             NSUB   = 0.6E15   
+ KP     = 1.5E-5          UO     = 400             
+ VMAX   = 0               XJ     = 5E-7          KAPPA  = 5E-4
+ ETA    = 1E-4            TPG    = -1  
+ IS     = 0               LD     = 0                        
+ CGSO   = 0               CGDO   = 0             CGBO   = 0 
+ NFS    = 0.8E12	   DELTA  = 0.1)
*****************************************************************
.MODEL  NMOS        NMOS ( LEVEL  = 3             TOX    = 1.7E-8
+NSUB    = 4E17            TPG    = 1)   
*****************************************************************
.MODEL DBD D (CJO=160E-12 VJ=0.38 M=0.33
+RS=0.1 FC=0.5 IS=1E-12 TT=6.7E-8 N=1 BV=12.2)
*****************************************************************
.MODEL RTEMP RES (TC1=4.5E-3 TC2=5.5E-6)
*****************************************************************
.ENDS Si1417EDH
.subckt Si1417EDH_ESD 1 5 2
rd7 1 9 40k TC=0.02
d7 9 2 dleak  
.MODEL dleak d (IS=1.2e-8 XTI=410 EG=1.17 T_MEASURED=25 TBV1=0 N=50 BV=6.4) 
rd3 1 10 125 TC=-0.002
d3 11 10 dout 1.422
d4 11 12 dout 1.422
d5 13 12 dout 1.78
d6 13 2  dout 1.78
.MODEL dout D (IS=5.1E-9 XTI=-35 EG=1.17 T_MEASURED=25 TBV1=-6.65e-4 N=2.05 BV=6.39)
rpoly 1 5 4K TC=0.001
rd8 5 14 1 
d8 15 14 din  
d9 15 2 din  
.MODEL din D (IS=5.1E-9 XTI=-20 EG=1.17 T_MEASURED=25 TBV1=0 N=2.05 BV=6.43)
.ends Si1417EDH_ESD