*February 20, 2006
*Doc. ID: 75991, S-60245, Rev. B
*File Name: Si4860DY_PS.txt and Si4860DY_PS.lib
*This document is intended as a SPICE modeling guideline and does not
*constitute a commercial product data sheet.  Designers should refer to the
*appropriate data sheet of the same number for guaranteed specification
*limits.
.SUBCKT Si4860DY 4 1 2
M1  3 1 2 2 NMOS W=2747286u L=0.50u   
M2  2 1 2 4 PMOS W=2747286u L=0.40u  
R1  4 3     RTEMP 3.7E-3
CGS 1 2     870E-12
DBD 2 4     DBD
**************************************************************************
.MODEL  NMOS       NMOS (  LEVEL  = 3               TOX    = 5E-8
+ RS     = 1.95E-3         RD     = 0               NSUB   = 1.75E17   
+ KP     = 2.8E-5          UO     = 650             
+ VMAX   = 0               XJ     = 5E-7            KAPPA  = 1E-2
+ ETA    = 1E-4            TPG    = 1  
+ IS     = 0               LD     = 0                             
+ CGSO   = 0               CGDO   = 0               CGBO   = 0 
+ NFS    = 0.8E12          DELTA  = 0.1)
*************************************************************************
.MODEL  PMOS       PMOS (LEVEL    = 3               TOX    = 5E-8
+NSUB    = 1.9E16          TPG    = -1)   
*************************************************************************
.MODEL DBD D (CJO=1400E-12  VJ=.38  M=0.33 
+FC=0.1 IS=1E-12 TT=4E-8 N=1 BV=30.2)
*************************************************************************
.MODEL RTEMP RES (TC1=7E-3  TC2=5.5E-6)
*************************************************************************
.ENDS