*April 10, 2006
*Doc. ID: 76010, S-60542, Rev. B
*This document is intended as a SPICE modeling guideline and does not
*constitute a commercial product data sheet.  Designers should refer to the
*appropriate data sheet of the same number for guaranteed specification
*limits.
.SUBCKT Si7703EDN D G S A K
X1 D G S Si7703
X2 A K   Si7703EDN_SCHOTTKY
.ENDS Si7703EDN
.SUBCKT Si7703 4 1 2
M1   3 5 2 2 PMOS W=687310u L=0.5u
M2   2 5 2 4 NMOS W=687310u L=1.0u
R1   4 3     RTEMP 14E-3
CGS  5 2     620E-12
DBD  4 2     DBD
XESD 1 5 2   Si7703EDN_ESD
*****************************************************************
.MODEL  PMOS       PMOS (  LEVEL  = 3            TOX    = 1.7E-8
+ RS     = 15E-3           RD     = 0            NSUB   = 6E15   
+ KP     = 2E-5            UO     = 400             
+ VMAX   = 0               XJ     = 5E-7         KAPPA  = 4E-3
+ ETA    = 1E-4            TPG    = -1  
+ IS     = 0               LD     = 0                        
+ CGSO   = 0               CGDO   = 0            CGBO   = 0 
+ TLEV   = 1               BEX    = -1.5         TCV    = 1.65E-3
+ NFS    = 0.8E12	   DELTA  = 0.1)
*****************************************************************
.MODEL  NMOS       NMOS (  LEVEL  = 3            TOX    = 1.7E-8
+NSUB    = 2.5E16          TPG    = 1)   
*****************************************************************
.MODEL DBD D (CJO=350E-12 VJ=0.38 M=0.33
+RS=0.05 FC=0.5 IS=1E-12 TT=6.7E-8 N=1 BV=20.5)
*****************************************************************
.MODEL RTEMP R (TC1=6.3E-3 TC2=5.5E-6)
*****************************************************************
.ENDS Si7703
.subckt Si7703EDN_SCHOTTKY 4 2
r1 4 6 rtemp 1e-4
d1 6 2 sdiode 
****************************************************
.model sdiode d (cjo=145e-12 vj=0.45 xti=2 
+rs=0.08 fc=0.5 is=1e-6 ik=0.8 eg=0.55 n=1 bv=22)
****************************************************
.model rtemp r (tc1=0.15e-2 tc2=30e-6)
.ENDS Si7703EDN_SCHOTTKY 
****************************************************
.subckt Si7703EDN_ESD 1 5 2
rd7 2 9 40k TC=0.02
d7 9 1 dleak M=1
.MODEL dleak d (IS=3e-9 XTI=410 EG=1.17 TREF=25 TCV=0 N=39 BV=6.4) 
rd3 2 10 105 TC=-0.002
d3 11 10 dout M=1.422
d4 11 12 dout M=1.422
d5 13 12 dout M=1.78
d6 13 1  dout M=1.78
.MODEL dout D (IS=1E-10 XTI=-35 EG=1.17 TREF=25 TCV=5e-3 N=2.05 BV=6.14)
rpoly 1 5 6.4K TC=0.001
rd8 2 14 1 
d8 15 14 din M=1
d9 15 5  din M=1
.MODEL din D (IS=3E-10 XTI=-20 EG=1.17 TREF=25 TCV=1e-3 N=2.05 BV=6.33)
.ENDS Si7703EDN_ESD