*June 13 2005
*Doc. ID: 76033, S-51095, Rev. B
*File Name: Si4480DY_PS.txt and Si4480DY_PS.lib
.SUBCKT Si4480DY 4 1 2    
M1  3 1 2 2 NMOS W=852508u L=0.5u 
M2  2 1 2 4 PMOS W=852508u L=1.2u
R1  3 4 RTEMP 21.5E-3
CGS 1 2 1600E-12
DBD 2 4 DBD
**************************************************************************
.MODEL  NMOS       NMOS (  LEVEL  = 3               TOX    = 6.5E-8
+ RS     = 3.0E-3          RD     = 0               NSUB   = 22.3E16
+ KP     = 4.3E-5          UO     = 200             
+ VMAX   = 0               XJ     = 5E-7            KAPPA  = 0.54E-1
+ ETA    = 1E-4            TPG    = 1  
+ IS     = 0               LD     = 0                             
+ CGSO   = 0               CGDO   = 0               CGBO   = 0 
+ NFS    = 0.8E12          DELTA  = 0.1)
*************************************************************************
.MODEL  PMOS PMOS         (LEVEL  = 3	            TOX    = 7.5E-8 
+NFS     = 17E16           TPG    = 1               NSUB   = 1.9E16)
*************************************************************************
.MODEL DBD D(CJO=1000E-12        VJ=0.38	        M=0.35	FC=0.5 
+RS=.07       	IS=1E-12	 TT=2.5E-8	N=1	BV=60.2)
*************************************************************************
.MODEL RTEMP RES (TC1=7.5E-3 TC2=8.5E-6)
*************************************************************************
.ENDS