*November 27, 2006
*Doc. ID: 76217, S-62306, Rev. B
*This document is intended as a SPICE modeling guideline and does not
*constitute a commercial product data sheet.  Designers should refer to the
*appropriate data sheet of the same number for guaranteed specification
*limits.
.SUBCKT SUM50N03-13LC D G S KELVIN SENSE
XM1  D G KELVIN SUM50N03N
XM2  D G SENSE  SUM50N03SENSE
RS  KELVIN  S  5E-6
.ENDS SUM50N03-13LC
.SUBCKT SUM50N03N D G S
M1  3 G S S NMOS W=2494220u L=0.50u    
M2  S G S D PMOS W=2494220u L=0.65u 
R1  D 3     RTEMP 5.5E-3
CGS G S     1150E-12
DBD S D     DBD
************************************************************** 
.MODEL  NMOS        NMOS ( LEVEL  = 3          TOX    = 5E-8
+ RS     = 4.2E-3          RD     = 0          NSUB   = 1.9E17   
+ KP     = 3.2E-5          UO     = 650             
+ VMAX   = 0               XJ     = 5E-7       KAPPA  = 25E-2
+ ETA    = 1E-4            TPG    = 1  
+ IS     = 0               LD     = 0                             
+ CGSO   = 0               CGDO   = 0          CGBO   = 0 
+ TLEV   = 1               BEX    = -1.5       TCV    = 3.3E-3
+ NFS    = 0.8E12          DELTA  = 0.1)
************************************************************** 
.MODEL  PMOS        PMOS ( LEVEL  = 3          TOX    = 5E-8
+NSUB    = 1.4E16          TPG    = -1)           
 ************************************************************* 
.MODEL DBD D (CJO=900E-12 VJ=0.38 M=0.30
+RS=0.1 FC=0.1 IS=1E-12 TT=5E-8 N=1 BV=30.2)
************************************************************** 
.MODEL RTEMP R (TC1=8E-3 TC2=5.5E-6)
************************************************************** 
.ENDS SUM50N03N
.SUBCKT SUM50N03SENSE D G S
M1  3 G S S NMOS W=6083u L=0.50u    
R1  D 3     RTEMP 2.255
CGS G S     2.8E-12
DBD S D     DBD 0.00244
************************************************************** 
.MODEL  NMOS       NMOS (  LEVEL  = 3          TOX    = 5E-8
+ RS     = 1.722           RD     = 0          NSUB   = 1.9E17   
+ KP     = 3.2E-5          UO     = 650             
+ VMAX   = 0               XJ     = 5E-7       KAPPA  = 25E-2
+ ETA    = 1E-4            TPG    = 1  
+ IS     = 0               LD     = 0                             
+ CGSO   = 0               CGDO   = 0          CGBO   = 0 
+ TLEV   = 1               BEX    = -1.5       TCV    = 3.3E-3
+ NFS    = 0.8E12          DELTA  = 0.1)
************************************************************** 
.MODEL DBD D (CJO=900E-12 VJ=0.38 M=0.30
+RS=0.1 FC=0.1 IS=1E-12 TT=5E-8 N=1 BV=30.2)
************************************************************** 
.MODEL RTEMP R (TC1=8E-3 TC2=5.5E-6)
************************************************************** 
.ENDS SUM50N03SENSE