*Oct 31, 2005
*Doc. ID: 76282, S-52296, Rev. B
.SUBCKT Si4501ADY D G1 S1 G2 S2 
X1 D G1 S1 Si4501N
X2 D G2 S2 Si4501P
.ENDS Si4501ADY
*N-CH
.SUBCKT Si4501N D G S   
M1  3 G S S NMOS W=2119936u L=0.50u     
M2  S G S D PMOS W=2119936u L=0.60u   
R1  D 3     RTEMP 2.2E-3 
CGS G S     500E-12
DBD S D     DBD
****************************************************************** 
.MODEL  NMOS        NMOS ( LEVEL  = 3            TOX    = 6.5E-8
+ RS     = 9.6E-3          RD     = 0            NSUB   = 0.93E17   
+ KP     = 1.35E-5         UO     = 650             
+ VMAX   = 0               XJ     = 5E-7         KAPPA  = 40E-2
+ ETA    = 1E-4            TPG    = 1  
+ IS     = 0               LD     = 0                             
+ CGSO   = 0               CGDO   = 0            CGBO   = 0 
+ TLEV   = 1               BEX    = -1.5         TCV    = 3.6E-3
+ NFS    = 0.8E12          DELTA  = 0.1)
****************************************************************** 
.MODEL  PMOS        PMOS ( LEVEL  = 3            TOX    = 6.5E-8
+NSUB    = 2.2E16          TPG    = -1)   
****************************************************************** 
.MODEL DBD D (CJO=400E-12 VJ=0.38 M=0.30 
+FC=0.1 IS=1E-12 TT=4E-8 N=1 BV=30.2)
****************************************************************** 
.MODEL RTEMP R (TC1=11E-3 TC2=5.5E-6)
****************************************************************** 
.ENDS Si4501N
*P-CH
.SUBCKT Si4501P D G S  
M1  3 G S S PMOS W=581570u L=0.50u  
M2  S G S D NMOS W=581570u L=1.10u 
R1  D 3     RTEMP 1E-3  
CGS G S     300E-12
DBD D S     DBD
*****************************************************************
.MODEL  PMOS        PMOS ( LEVEL  = 3             TOX    = 1.7E-8
+ RS     = 19E-3           RD     = 0             NSUB   = 1.15E16   
+ KP     = 2.1E-5          UO     = 400             
+ VMAX   = 0               XJ     = 5E-7          KAPPA  = 5E-3
+ ETA    = 1E-4            TPG    = -1  
+ IS     = 0               LD     = 0                        
+ CGSO   = 0               CGDO   = 0             CGBO   = 0 
+ TLEV   = 1               BEX    = -1.5          TCV    = 2.3E-3
+ NFS    = 0.8E12	   DELTA  = 0.1)
*****************************************************************
.MODEL  NMOS        NMOS ( LEVEL  = 3             TOX    = 1.7E-8
+NSUB    = 5E17            TPG    = 1)   
*****************************************************************
.MODEL DBD D (CJO=400E-12 VJ=0.38 M=0.38
+RS=0.1 FC=0.5 IS=1E-12 TT=6E-8 N=1 BV=8.2)
*****************************************************************
.MODEL RTEMP R (TC1=10.5E-3 TC2=5.5E-6)
*****************************************************************
.ENDS Si4501P