*Feb. 28, 2005
*Doc. ID: 76361, S-50232, Rev. B
*File Name: Si1563DH_PS.txt and Si1563DH_PS.lib
*Dn Gn Sn Dp Gp Sp
.SUBCKT Si1563DH 6 2 1 3 5 4  
X1 6 2 1 Si1563N
X2 3 5 4 Si1563P
.ENDS Si1563DH
*N-Ch
.SUBCKT Si1563N 4 1 2   
M1  3 1 2 2 NMOS W=55269u L=0.50u 
M2  2 1 2 4 PMOS W=55269u L=0.90u 
R1  4 3     RTEMP 95E-3
CGS 1 2     60E-12
DBD 2 4     DBD
************************************************************  
.MODEL  NMOS         NMOS (LEVEL  = 3        TOX    = 1.7E-8
+ RS     = 70E-3           RD     = 0        NSUB   = 1.63E17   
+ KP     = 5.2E-5          UO     = 650             
+ VMAX   = 0               XJ     = 5E-7     KAPPA  = 10E-2
+ ETA    = 1E-4            TPG    = 1  
+ IS     = 0               LD     = 0                        
+ CGSO   = 0               CGDO   = 0        CGBO   = 0 
+ NFS    = 0.8E12          DELTA  = 0.1)
************************************************************  
.MODEL  PMOS         PMOS (LEVEL  = 3        TOX    = 1.7E-8
+NSUB    = 4E16            TPG    = -1)   
************************************************************  
.MODEL DBD D (CJO=40E-12 VJ=0.38 M=0.30
+RS=1 FC=0.1 IS=1E-12 TT=4E-8 N=1 BV=20.5)
************************************************************ 
.MODEL RTEMP RES (TC1=6E-3 TC2=5.5E-6)
************************************************************  
.ENDS Si1563N
*P-Ch
.SUBCKT Si1563P 4 1 2  
M1  3 1 2 2 PMOS W=55269u L=0.50u 
M2  2 1 2 4 NMOS W=55269u L=0.90u 
R1  4 3     RTEMP 150E-3
CGS 1 2     45E-12
DBD 4 2     DBD
*****************************************************************
.MODEL  PMOS       PMOS (  LEVEL  = 3             TOX    = 1.7E-8
+ RS     = 100E-3          RD     = 0             NSUB   = 0.8E15   
+ KP     = 1.6E-5          UO     = 400             
+ VMAX   = 0               XJ     = 5E-7          KAPPA  = 1E-4
+ ETA    = 1E-4            TPG    = -1  
+ IS     = 0               LD     = 0                        
+ CGSO   = 0               CGDO   = 0             CGBO   = 0 
+ NFS    = 0.8E12	   DELTA  = 0.1)
*****************************************************************
.MODEL  NMOS       NMOS (  LEVEL  = 3             TOX    = 1.7E-8
+NSUB    = 7E16            TPG    = 1)   
*****************************************************************
.MODEL DBD D (CJO=40E-12 VJ=0.38 M=0.33
+RS=1 FC=0.5 IS=1E-12 TT=6.7E-8 N=1 BV=20.2)
*****************************************************************
.MODEL RTEMP RES (TC1=5.8E-3 TC2=5.5E-6)
*****************************************************************
.ENDS Si1563P