*Nov 21, 2005
*Doc. ID: 76376, S-52398, Rev. B
*File Name: Si9424BDY_PS.txt and Si9424BDY_PS.lib
.SUBCKT Si9424BDY 4 1 2                                         
M1  3 1 2 2 PMOS W=194577u L=0.25u 
M2  2 1 2 4 NMOS W=194577u L=4.70u 
R1  4 3     RTEMP 23E-4
CGS 1 2     1800E-12
DBD 4 2     DBD
**************************************************************************
.MODEL  PMOS       PMOS (  LEVEL  = 3               TOX    = 1.7E-8
+ RS     = 80E-4           RD     = 0               NSUB   = 2.5E16   
+ KP     = 1.3E-4          UO     = 400             
+ VMAX   = 0               XJ     = 5E-7            KAPPA  = 5E-3
+ ETA    = 1E-4            TPG    = -1  
+ IS     = 0               LD     = 0                            
+ CGSO   = 0               CGDO   = 0               CGBO   = 0 
+ NFS    = 0.8E12          DELTA  = 0.1)
*************************************************************************
.MODEL  NMOS       NMOS (  LEVEL  = 3               TOX    = 1.7E-8
+NSUB    = 1.1E17          TPG    = -1)   
*************************************************************************
.MODEL DBD D (CJO=400E-12 VJ=0.38 M=0.38
+FC=0.5 IS=1E-11 TT=3.7E-8 N=1 BV=20.5)
*************************************************************************
.MODEL RTEMP RES (TC1=14E-3  TC2=5.5E-6)
*************************************************************************
.ENDS