*August 22, 2005
*Doc. ID: 76380, S-51551, Rev. B
*Dn Gn Sn Dp Gp Sp
.SUBCKT Si7872DP 8 2 1 6 4 3  
X1 8 2 1 Si7872C1
X2 6 4 3 Si7872C2
R1 1 6 1E-6
.ENDS Si7872DP
*Channel 1
.SUBCKT Si7872C1 4 1 2 
M1  3 1 2 2 NMOS W=1358279u L=0.50u  
M2  2 1 2 4 PMOS W=1358279u L=0.40u
R1  4 3     RTEMP 11E-3
CGS 1 2     450E-12
DBD 2 4     DBD
************************************************************  
.MODEL  NMOS         NMOS (LEVEL  = 3        TOX    = 5E-8
+ RS     = 4.3E-3          RD     = 0        NSUB   = 1.77E17  
+ KP     = 2.1E-5          UO     = 650             
+ VMAX   = 0               XJ     = 5E-7     KAPPA  = 7E-2
+ ETA    = 1E-4            TPG    = 1  
+ IS     = 0               LD     = 0                             
+ CGSO   = 0               CGDO   = 0        CGBO   = 0 
+ TLEV   = 1               BEX    = -1.5     TCV    = 4.3E-3
+ NFS    = 0.8E12          DELTA  = 0.1)
************************************************************  
.MODEL  PMOS         PMOS (LEVEL  = 3        TOX    = 5E-8
+NSUB    = 2.1E16          TPG    = -1)   
************************************************************  
.MODEL DBD D (CJO=210E-12 VJ=0.38 M=0.22
+RS=0.01 FC=0.1 IS=1E-12 TT=2.8E-8 N=1 BV=30.2)
************************************************************ 
.MODEL RTEMP R (TC1=6.5E-3  TC2=5.5E-6)
************************************************************  
.ENDS Si7872C1
*Channel 2
.SUBCKT Si7872C2  4 1 2 
M1  3 1 2 2 NMOS W=1358279u L=0.50u   
M2  2 1 2 4 PMOS W=1358279u L=0.40u 
R1  4 3     RTEMP 7.6E-3
CGS 1 2     700E-12
DBD 2 4     DBD
XSD 2 4     SCHOTTKY
************************************************************  
.MODEL  NMOS         NMOS (LEVEL  = 3        TOX    = 3E-8
+ RS     = 7E-3            RD     = 0        NSUB   = 2.7E17  
+ KP     = 2.6E-5          UO     = 650             
+ VMAX   = 0               XJ     = 5E-7     KAPPA  = 7E-2
+ ETA    = 1E-4            TPG    = 1  
+ IS     = 0               LD     = 0                             
+ CGSO   = 0               CGDO   = 0        CGBO   = 0 
+ TLEV   = 1               BEX    = -1.5     TCV    = 2.8E-3
+ NFS    = 0.8E12          DELTA  = 0.1)
************************************************************  
.MODEL  PMOS         PMOS (LEVEL  = 3        TOX    = 3E-8
+NSUB    = 5E16            TPG    = -1)   
************************************************************  
.MODEL DBD D (CJO=400E-12 VJ=0.38 M=0.30
+RS=0.01 FC=0.1 IS=1E-12 TT=2.8E-8 N=1 BV=30.2)
************************************************************ 
.MODEL RTEMP R (TC1=7.5E-3  TC2=5.5E-6)
************************************************************  
.ENDS Si7872C2
.subckt schottky 7 5
 r1 6 5  rtemp 0.04
 d1 7 6  sdiode 
****************************************************
.model sdiode d (cjo=200e-12 vj=0.60 xti=0.50 
+rs=0 fc=0.50 is=1.5e-6 ik=0.20 eg=0.90 n=1 bv=30.2)
****************************************************
.model rtemp r (tc1=0.01e-2 tc2=20e-6)
.ends schottky