*Feb 28, 2005
*Doc. ID: 76385, S-50232, Rev. B
*File Name: Si2301BDS_ps.txt and Si2301BDS_ps.lib
.SUBCKT Si2301BDS 4 1 2                                         
M1  3 1 2 2 PMOS W=323966u L=0.40u 
M2  2 1 2 4 NMOS W=323966u L=0.60u 
R1  4 3     RTEMP 35E-3
CGS 1 2     50E-12
DBD 4 2     DBD
**************************************************************************
.MODEL  PMOS       PMOS (  LEVEL  = 3               TOX    = 1.7E-8
+ RS     = 40E-3           RD     = 0               NSUB   = 7E15   
+ KP     = 2E-5            UO     = 400             
+ VMAX   = 0               XJ     = 5E-7            KAPPA  = 4E-3
+ ETA    = 1E-4            TPG    = -1  
+ IS     = 0               LD     = 0                            
+ CGSO   = 0               CGDO   = 0               CGBO   = 0 
+ NFS    = 0.8E12          DELTA  = 0.1)
*************************************************************************
.MODEL  NMOS       NMOS (  LEVEL  = 3               TOX    = 1.7E-8
+NSUB    = 1E17            TPG    = -1)   
*************************************************************************
.MODEL DBD D (CJO=40E-12 VJ=0.38 M=0.22
+FC=0.5 IS=1E-12 TT=5E-8 N=1 BV=20.5)
*************************************************************************
.MODEL RTEMP RES (TC1=6.5E-3 TC2=5.5E-6)
*************************************************************************
.ENDS