*Feb 13, 2006
*Doc. ID: 76412, S-60147, Rev. B
*File Name: Si6969BDQ_PS.txt and Si6969BDQ_PS.lib
*This document is intended as a SPICE modeling guideline and does not
*constitute a commercial product data sheet.  Designers should refer to the
*appropriate data sheet of the same number for guaranteed specification
*limits.
.SUBCKT Si6969BDQ  4 1 2
M1  3 1 2 2 PMOS W=1125978u L=0.50u       
M2  2 1 2 4 NMOS W=1125978u L=0.75u  
R1  4 3     RTEMP 6E-3
CGS 1 2     40E-12
DBD 4 2     DBD
**************************************************************** 
.MODEL  PMOS       PMOS (  LEVEL  = 3           TOX    = 1.7E-8
+ RS     = 10E-3           RD     = 0           NSUB   = 3.55E15   
+ KP     = 2.4E-5          XJ     = 5E-7        KAPPA  = 10E-3
+ ETA    = 1E-4            TPG    = -1  
+ IS     = 0               LD     = 0                  
+ CGSO   = 0               CGDO   = 0           CGBO   = 0 
+ NFS    = 0.8E12	   DELTA  = 0.1)
**************************************************************** 
.MODEL  NMOS       NMOS (  LEVEL  = 3           TOX    = 1.7E-8
+NSUB    = 2E17            TPG    = 1)   
**************************************************************** 
.MODEL DBD D (CJO=350E-12 VJ=0.38 M=0.38
+RS=0.1 FC=0.5 IS=1E-12 TT=6.7E-8 N=1 BV=12.2)
**************************************************************** 
.MODEL RTEMP RES (TC1=8E-3 TC2=5.5E-6)
**************************************************************** 
.ENDS