*November 27, 2006
*Doc. ID: 76518, S-62312, Rev. C
*This document is intended as a SPICE modeling guideline and does not
*constitute a commercial product data sheet.  Designers should refer to the
*appropriate data sheet of the same number for guaranteed specification
*limits.
.SUBCKT SUM110N04-04 D G S
M1  3 G S S NMOS W=10531082u L=0.50u   
M2  S G S D PMOS W=10531082u L=0.80u  
R1  D 3     RTEMP 1.7E-3
CGS G S     4100E-12
DBD S D     DBD
**************************************************************** 
.MODEL  NMOS       NMOS (  LEVEL  = 3           TOX    = 7E-8
+ RS     = 0.7E-3          RD     = 0           NSUB   = 2.65E17   
+ KP     = 2E-5            UO     = 650             
+ VMAX   = 0               XJ     = 5E-7        KAPPA  = 38E-2
+ ETA    = 1E-4            TPG    = 1  
+ IS     = 0               LD     = 0                             
+ CGSO   = 0               CGDO   = 0           CGBO   = 0 
+ TLEV   = 1               BEX    = -1.5        TCV    = 5.3E-3
+ NFS    = 0.8E12          DELTA  = 0.1)
***************************************************************** 
.MODEL  PMOS       PMOS (  LEVEL  = 3           TOX    = 7E-8
+NSUB    = 2E16            IS     = 0		TPG    = -1)           
 **************************************************************** 
.MODEL DBD D (CJO=2000E-12 VJ=0.38 M=0.38 EG=1.17
+FC=0.1 TT=5E-8 TREF=25 BV=41
+IS=3.898e-11 RS=1.368e-03 N=1.126
+XTI=3.196 TRS=3.101e-03)
***************************************************************** 
.MODEL RTEMP R (TC1=8E-3 TC2=5.5E-6)
***************************************************************** 
.ENDS