*July 23, 2007
*Doc. ID: 76554, S-71510, Rev. B
*This document is intended as a SPICE modeling guideline and does not
*constitute a commercial product data sheet.  Designers should refer to the
*appropriate data sheet of the same number for guaranteed specification
*limits.
.SUBCKT SUP40N10-30 4 1 2
M1  3 1 2 2 NMOS W=4023564u L=0.25u     
M2  2 1 2 4 PMOS W=4023564u L=0.60u 
R1  4 3     RTEMP 16E-3
CGS 1 2     1600E-12
DBD 2 4     DBD
**************************************************************************
.MODEL  NMOS       NMOS (  LEVEL  = 3               TOX    = 7E-8
+ RS     = 6E-3            RD     = 0               NSUB   = 2.55E17
+ KP     = 6E-6            U0     = 650
+ VMAX   = 0               XJ     = 5E-7            KAPPA  = 70E-3
+ ETA    = 1E-4            TPG    = 1  
+ IS     = 0               LD     = 0                             
+ CGSO   = 0               CGDO   = 0               CGBO   = 0 
+ TLEV   = 1               BEX    = -1.5            TCV    = 7.7E-3
+ NFS    = 0.8E12          DELTA  = 0.1)
*************************************************************************
.MODEL  PMOS       PMOS (LEVEL    = 3               TOX    = 7E-8
+NSUB    = 5E15            TPG    = -1)           
 *********************************************************************
.MODEL DBD D (CJO=640E-12 VJ=0.38 M=0.34
+RS=0.1 FC=0.1 IS=1E-12 TT=5E-8 N=1 BV=100.2)
*************************************************************************
.MODEL RTEMP R (TC1=8E-3 TC2=5.5E-6)
*************************************************************************
.ENDS