*Feb 20, 2006
*Doc. ID: 76577, S-60245, Rev. B
*File Name: Si7844DP_PS.txt and Si7844DP_PS.lib
*This document is intended as a SPICE modeling guideline and does not
*constitute a commercial product data sheet.  Designers should refer to the
*appropriate data sheet of the same number for guaranteed specification
*limits.
.SUBCKT Si7844DP 4 1 2
M1  3 1 2 2 NMOS W=1117382u L=0.90u 
M2  2 1 2 4 PMOS W=1117382u L=0.60u 
R1  4 3     RTEMP 80E-4
CGS 1 2     130E-12
DBD 2 4     DBD
******************************************************************* 
.MODEL  NMOS       NMOS ( LEVEL  = 3               TOX    = 6.5E-8
+ RS     = 45E-4          RD     = 0               NSUB   = 4.95E16  
+ kp     = 2.9E-5         UO     = 650             
+ VMAX   = 0              XJ     = 5E-7            KAPPA  = 3.6E-1
+ ETA    = 1E-4           TPG    = 1  
+ IS     = 0              LD     = 0                           
+ CGSO   = 0              CGDO   = 0               CGBO   = 0 
+ NFS    = 0.8E12         DELTA  = 0.1)
******************************************************************* 
.MODEL  PMOS       PMOS ( LEVEL  = 3               TOX    = 6.5E-8
+NSUB    = 5E16           TPG    = -1)   
******************************************************************* 
.MODEL DBD D (CJO=480E-12 VJ=0.38 M=0.32
+RS=0.5 FC=0.5 IS=1E-12 TT=4.9E-8 N=1 BV=30.5)
******************************************************************* 
.MODEL RTEMP RES (TC1=5.4E-3 TC2=5.5E-6)
******************************************************************* 
.ENDS