*==========================================================
* Vishay SI4724CY
* March 14, 2005
* Doc. ID: 76694, S-50464, Rev. B
*
* This model was developed for Vishay by:
* AEI Systems, LLC
* 5777 W. Century Blvd. Suite 876
* Los Angeles, California 90045
* Copyright 2003, all rights reserved.
*
* This model is subject to change without notice.
* Users may not directly or indirectly re-sell or 
* re-distribute this model. 
*
* For more information regarding modeling services,
* model libraries and simulation products, please
* call AEi Systems at (310) 216-1144, or contact 
* AEi by email: info@aeng.com. http://www.AENG.com
*
* Revision: 6/3/02, version 1.1
* Revision: 1/28/04, version 1.1
*             Updated driver voltages and VTO to reduce IC current draw.
*                 Note, do not trust spice to have accurate currents.
**********
.SUBCKT Si4724CY VDD Sync Vin Gnd Boot D1 S1 D2 S2
*                VDD Sync Vin Gnd Boot D1 S1 D2 S2
* #alias bbm  v(bbm)
* #alias g1  v(g1)
* #alias in  v(vin)
* #alias syncin  v(18)
* #alias in2  v(in2)
* #alias in3  v(in3)
* #alias vout  v(5)
* #alias vswitch  v(s1)
* #alias vboot  v(boot)
* #alias vdduvlo  v(vdduvlo)
* #alias g2  v(g2)

EB1 15 gnd Value={ IF ( V(Sync) > 2.3, 5, 0 ) }

Q1 Boot Boot Vdd SIDVRABSD
.MODEL SIDVRABSD PNP BF=1.2465499 BR=0.0743382
+ CJC=2.48725E-10 CJE=1.45909E-10 EG=1.32 FC=0.5
+ IKF=10.6793593 IKR=100 IRB=9.494516E-6 IS=5.828556E-18
+ ISC=5.929013E-14 ISE=3.690477E-15 MJC=0.3677641
+ MJE=0.3267463 NC=1.47 NE=1.0479867 NF=0.9018194
+ NR=1.0087761 RB=130.4148594 RBM=0.0957343 RC=80
+ RE=1.0245273 TR=7.68E-7 VAF=1E4 VAR=2E4 VJC=0.6097614
+ VJE=0.803 XTB=3.4 XTI=0.5


EB5 8 G1 Value={ IF ( V(VDDUvlo) > 1 & V(16) > 4, 5, 0 ) }
R8 11 8 35
C3 G1 11 30p
X3 D2 G2 S2 SIFETADY 
R2 14 16 200
C1 16 gnd 100p
EB2 In2 gnd Value={ IF ( V(16) > 4, 5, 0 ) }
R10 15 18 170
C5 18 gnd 200p
EB3 In3 gnd Value={ IF ( V(16) > 2.2, 5, 0 ) }
EBIN 14 gnd Value={ IF ( V(Vin) > 2.3, 5, 0 ) }
XS2 25 VDDUvlo Vdd 0 _S2_mod  PARAMS: VT=3.8 VH=.2 ROFF=10meg
V7 25 0 DC=10
R5 VDDUvlo gnd 1
EB7 BBM gnd Value={ IF ( V(S1) > 2.4, 5, 0 ) }
D3 S2 D2 SISCHC2
.MODEL SISCHC2 D BV=30.2 CJO=200p EG=0.9 FC=0.50 IS=1.5u
+ N=1 RS=0 VJ=0.6 XTI=0.50
EB4 27 G2 Value={ IF (V(VDDUvlo) > 1 & V(16) < 2.2 & V(18) > 1 & V(BBM) < 1, 5, 0 ) }
R6 12 27 10
C2 12 G2 20p
X4 D1 G1 S1 SIFETADY 
M9 S1 11 G1 G1 SIDVRAFETPh 
.MODEL SIDVRAFETPh PMOS Level=1 CBD=530p CBS=636p
+ CGBO=1.07u CGDO=650n CGSO=780n GAMMA=0 IS=1.00p KP=75.0m
+ LAMBDA=2.50m MJ=0.460 PB=0.800 PHI=.75 RD=0.210 RS=0.210
+ VTO=2
M10 Gnd 12 G2 G2 SIDVRAFETPL
.MODEL SIDVRAFETPL PMOS Level=1 CBD=530p CBS=636p
+ CGBO=1.07u CGDO=650n CGSO=780n GAMMA=0 IS=1.00p KP=75.0m
+ LAMBDA=2.50m MJ=0.460 PB=0.800 PHI=.75 RD=0.140 RS=0.140
+ VTO=2
M11 Boot 11 G1 G1 SIDVRAFETNh
.MODEL SIDVRAFETNh NMOS Level=1 CBD=530p CBS=636p
+ CGBO=1.07u CGDO=650n CGSO=780n GAMMA=0 IS=1.00p KP=75.0m
+ LAMBDA=2.50m MJ=0.460 PB=0.800 PHI=.75 RD=98.0m RS=98.0m
+ VTO=2
M12 Vdd 12 G2 G2 SIDVRAFETNL
.MODEL SIDVRAFETNL NMOS Level=1 CBD=530p CBS=636p
+ CGBO=1.07u CGDO=650n CGSO=780n GAMMA=0 IS=1.00p KP=75.0m
+ LAMBDA=2.50m MJ=0.460 PB=0.800 PHI=.75 RD=84.0m RS=84.0m
+ VTO=2
.ENDS

.SUBCKT SIFETADY 4 1 2
M1  3 1 2 2 NMOS W=1358279u L=0.50u  
M2  2 1 2 4 PMOS W=1358279u L=0.40u
R1  4 3     RTEMP 11E-3 
CGS 1 2     450E-12
DBD 2 4     DBD  
.MODEL  NMOS         NMOS (LEVEL  = 3        TOX    = 5E-8
+ RS     = 4.3E-3          RD     = 0        NSUB   = 1.77E17  
+ KP     = 2.1E-5          UO     = 650             
+ VMAX   = 0               XJ     = 5E-7     KAPPA  = 7E-2
+ ETA    = 1E-4            TPG    = 1  
+ IS     = 0               LD     = 0                             
+ CGSO   = 0               CGDO   = 0        CGBO   = 0 
+ NFS    = 0.8E12          DELTA  = 0.1)
.MODEL  PMOS         PMOS (LEVEL  = 3        TOX    = 5E-8
+NSUB    = 2.1E16          TPG    = -1)   
.MODEL DBD D (CJO=210E-12 VJ=0.38 M=0.22
+RS=0.01 FC=0.1 IS=1E-12 TT=2.8E-8 N=1 BV=30.2)
.MODEL RTEMP RES (TC1=6.5E-3 TC2=5.5E-6)
.ENDS

.subckt SWhyste NodeMinus NodePlus Plus Minus PARAMS: RON=1 ROFF=1MEG VT=5 VH=2
S5 NodePlus NodeMinus 8 0 smoothSW
EBcrtl 8 0 Value = { IF ( V(plus)-V(minus) > V(ref), 1, 0 ) }
EBref ref1 0 Value = { IF ( V(8) > 0.5, {VT-VH}, {VT+VH} ) }
Rdel ref1 ref 100
Cdel ref 0 100p  IC={VT+VH}
Rconv1 8 0 10Meg
Rconv2 plus 0 10Meg
Rconv3 minus 0 10Meg
.model smoothSW VSWITCH (RON={RON} ROFF={ROFF} VON=1 VOFF=0)
.ends