*Feb 13, 2006
*Doc. ID: 76704, S-60142, Rev. B
*This document is intended as a SPICE modeling guideline and does not
*constitute a commercial product data sheet.  Designers should refer to the
*appropriate data sheet of the same number for guaranteed specification
*limits.
*Dn Gn Sn Dp Gp Sp
.SUBCKT Si6544BDQ 6 2 1 3 5 4  
X1 6 2 1 Si6544N
X2 3 5 4 Si6544P
.ENDS Si6544BDQ
*N-Ch
.SUBCKT Si6544N 4 1 2
M1  3 1 2 2 NMOS W=876632u L=0.25u 
M2  2 1 2 4 PMOS W=876632u L=0.45u
R1  4 3     RTEMP 14E-3
CGS 1 2     460E-12
DBD 2 4     DBD
*************************************************************** 
.MODEL  NMOS       NMOS ( LEVEL  = 3           TOX    = 5E-8
+ RS     = 8E-3           RD     = 0           NSUB   = 2.76E17 
+ KP     = 13E-6          UO     = 650             
+ VMAX   = 0              XJ     = 5E-7        KAPPA  = 1E-2
+ ETA    = 1E-4           TPG    = 1  
+ IS     = 0              LD     = 0               
+ CGSO   = 0              CGDO   = 0           CGBO   = 0 
+ TLEV   = 1              BEX    = -1.9        TCV    = 5.1E-3
+ NFS    = 0.8E12         DELTA  = 0.1)
**************************************************************** 
.MODEL  PMOS       PMOS ( LEVEL  = 3           TOX    = 5E-8
+NSUB    = 2.5E16         TPG    = -1)   
**************************************************************** 
.MODEL DBD D (CJO=280E-12 VJ=0.38 M=0.26
+RS=0.1 FC=0.5 IS=1E-12 TT=5E-8 N=1 BV=81)
**************************************************************** 
.MODEL RTEMP R (TC1=11E-3 TC2=5.5E-6)
**************************************************************** 
.ENDS Si6544N
*P-CH
.SUBCKT Si6544P 4 1 2
M1  3 1 2 2 PMOS W=1193142u L=0.25u          
M2  2 1 2 4 NMOS W=1193142u L=0.40u
R1  4 3     RTEMP 7.6E-3
CGS 1 2     500E-12
DBD 4 2     DBD
***************************************************************  
.MODEL  PMOS       PMOS  ( LEVEL  = 3           TOX    = 5E-8
+ RS     = 17E-3           RD     = 0           NSUB   = 1.3E17
+ KP     = 4E-6            UO     = 400             
+ VMAX   = 0               XJ     = 5E-7        KAPPA  = 6E-2
+ ETA    = 1E-4            TPG    = -1  
+ IS     = 0               LD     = 0                        
+ CGSO   = 0               CGDO   = 0           CGBO   = 0 
+ TLEV   = 1               BEX    = -1.5        TCV    = 4.9E-3
+ NFS    = 0.8E12          DELTA  = 0.1)
*************************************************************** 
.MODEL  NMOS       NMOS  ( LEVEL  = 3           TOX    = 5E-8
+NSUB    = 1.5E17          NFS    = 1E12        TPG    = -1)   
*************************************************************** 
.MODEL DBD D (CJO=150E-12 VJ=0.38 M=0.34
+RS=0.1 FC=0.5 IS=1E-12 TT=6E-8 N=1 BV=30.2)
*************************************************************** 
.MODEL RTEMP R (TC1=13E-3 TC2=5.5E-6)
*************************************************************** 
.ENDS Si6544P