*April 10, 2006
*Doc. ID: 76728, S-60542, Rev. B
*This document is intended as a SPICE modeling guideline and does not
*constitute a commercial product data sheet.  Designers should refer to the
*appropriate data sheet of the same number for guaranteed specification
*limits.
.SUBCKT SUD50N02-04P 4 1 2
M1  3 1 2 2 NMOS W=7223878u L=0.25u 
M2  2 1 2 4 PMOS W=7223878u L=0.45u
R1  4 3     RTEMP 9E-4
CGS 1 2     3200E-12
DBD 2 4     DBD
************************************************************** 
.MODEL  NMOS       NMOS  (LEVEL  = 3           TOX    = 5E-8
+ RS     = 22E-4          RD     = 0           NSUB   = 2.7E17  
+ KP     = 11E-6          UO     = 650             
+ VMAX   = 0              XJ     = 5E-7        KAPPA  = 1E-2
+ ETA    = 1E-4           TPG    = 1  
+ IS     = 0              LD     = 0               
+ CGSO   = 0              CGDO   = 0           CGBO   = 0 
+ TLEV   = 1              BEX    = -1.4        TCV    = 4.5E-3
+ NFS    = 0.8E12         DELTA  = 0.1)
*************************************************************** 
.MODEL  PMOS       PMOS  (LEVEL  = 3           TOX    = 5E-8
+NSUB    = 5E16           TPG    = -1)   
*************************************************************** 
.MODEL DBD D (CJO=2500E-12 VJ=0.38 M=0.27
+RS=0.1 FC=0.5 IS=1E-12 TT=5E-8 N=1 BV=20.3)
*************************************************************** 
.MODEL RTEMP R (TC1=11E-3  TC2=5.5E-6)
*************************************************************** 
.ENDS