*July 23, 2007
*Doc. ID: 76878, S-71498, Rev. C
*This document is intended as a SPICE modeling guideline and does not
*constitute a commercial product data sheet.  Designers should refer to the
*appropriate data sheet of the same number for guaranteed specification
*limits.
*D1 G1 S1 D2 G2 S2
.SUBCKT Si4340DY 8 2 1 6 4 3  
X1    8 2 1 Si4340C1
X2    6 4 3 Si4340C2
R1    1 6   1E-6
XSDC2 3 6   Si4340C2_SCHOTTKY
.ENDS Si4340DY
*Channel 1
.SUBCKT Si4340C1 4 1 2
M1  3 1 2 2 NMOS W=1916590u L=0.25u      
M2  2 1 2 4 PMOS W=1916590u L=0.50u 
R1  4 3     RTEMP 5E-3
CGS 1 2     700E-12
DBD 2 4     DBD
*************************************************************** 
.MODEL  NMOS        NMOS ( LEVEL  = 3           TOX    = 5E-8
+ RS     = 3E-3            RD     = 0           NSUB   = 2.2E17
+ KP     = 1.2E-5          U0     = 650
+ VMAX   = 0               XJ     = 5E-7        KAPPA  = 5E-3
+ ETA    = 1E-4            TPG    = 1  
+ IS     = 0               LD     = 0                             
+ CGSO   = 0               CGDO   = 0           CGBO   = 0 
+ TLEV   = 1               BEX    = -1.5        TCV    = 4.7E-3
+ NFS    = 0.8E12          DELTA  = 0.1)
*************************************************************** 
.MODEL  PMOS       PMOS  ( LEVEL  = 3           TOX    = 5E-8
+NSUB    = 6E16            TPG    = -1)           
 ************************************************************** 
.MODEL DBD D (CJO=750E-12 VJ=0.38 M=0.30
+RS=0.1 FC=0.1 IS=1E-12 TT=5E-8 N=1 BV=20.2)
*************************************************************** 
.MODEL RTEMP R (TC1=15E-3 TC2=5.5E-6)
*************************************************************** 
.ENDS Si4340C1
*Channel 2
.SUBCKT Si4340C2 4 1 2
M1  3 1 2 2 NMOS W=2520733u L=0.25u     
M2  2 1 2 4 PMOS W=2520733u L=0.45u  
R1  4 3     RTEMP 2.2E-3
CGS 1 2     1500E-12
DBD 2 4     DBD
*************************************************************** 
.MODEL  NMOS        NMOS ( LEVEL  = 3           TOX    = 4E-8
+ RS     = 3.65E-3         RD     = 0           NSUB   = 2E17   
+ KP     = 1.3E-5          UO     = 650             
+ VMAX   = 0               XJ     = 5E-7        KAPPA  = 1E-3
+ ETA    = 1E-4            TPG    = 1  
+ IS     = 0               LD     = 0                             
+ CGSO   = 0               CGDO   = 0           CGBO   = 0 
+ TLEV   = 1               BEX    = -1.5        TCV    = 3.7E-3
+ NFS    = 0.8E12          DELTA  = 0.1)
**************************************************************** 
.MODEL  PMOS        PMOS ( LEVEL  = 3           TOX    = 4E-8
+NSUB    = 1E17            TPG    = -1)           
 *************************************************************** 
.MODEL DBD D (CJO=1200E-12 VJ=0.38 M=0.28
+RS=0.1 FC=0.1 IS=1E-12 TT=5E-8 N=1 BV=20.2)
**************************************************************** 
.MODEL RTEMP R (TC1=7E-3 TC2=5.5E-6)
**************************************************************** 
.ENDS Si4340C2
.subckt Si4340C2_SCHOTTKY 7 5
 r1 6 5  rtemp 0.04
 d1 7 6  sdiode 
****************************************************
.model sdiode d (cjo=200e-12 vj=0.60 xti=0.50 
+rs=0 fc=0.50 is=1.5e-6 ik=0.20 eg=0.90 n=1 bv=30.2)
****************************************************
.model rtemp r (tc1=0.01e-2 tc2=20e-6)
.ENDS Si4340C2_SCHOTTKY