*May 16, 2005
*Doc. ID: 76892, S-50836, Rev. B
*File Name: Si3981DV_PS.txt and Si3981DV_PS.lib
.SUBCKT Si3981DV 4 1 2
M1  3 1 2 2 PMOS W=186675u L=0.25u          
M2  2 1 2 4 NMOS W=186675u L=0.30u
R1  4 3     RTEMP 67E-3
CGS 1 2     200E-12
DBD 4 2     DBD
***************************************************************  
.MODEL  PMOS       PMOS  ( LEVEL  = 3           TOX    = 1.7E-8
+ RS     = 44E-3           RD     = 0           NSUB   = 2.09E16
+ KP     = 10E-6           UO     = 400             
+ VMAX   = 0               XJ     = 5E-7        KAPPA  = 6E-4
+ ETA    = 1E-4            TPG    = -1  
+ IS     = 0               LD     = 0                        
+ CGSO   = 0               CGDO   = 0           CGBO   = 0 
+ NFS    = 0.8E12          DELTA  = 0.1)
*************************************************************** 
.MODEL  NMOS       NMOS  ( LEVEL  = 3           TOX    = 1.7E-8
+NSUB    = 3E17            TPG    = -1)   
*************************************************************** 
.MODEL DBD D (CJO=70E-12 VJ=0.38 M=0.30
+RS=0.1 FC=0.5 IS=1E-12 TT=6E-8 N=1 BV=20.2)
*************************************************************** 
.MODEL RTEMP RES (TC1=5E-3 TC2=5.5E-6)
*************************************************************** 
.ENDS