*Feb. 28, 2005
*Doc. ID: 76910, S-50232, Rev. B
*File Name: Si2304BDS_PS.txt and Si2304BDS_PS.lib
.SUBCKT Si2304BDS 4 1 2
M1  3 1 2 2 NMOS W=345253u L=0.25u 
M2  2 1 2 4 PMOS W=345253u L=0.45u 
R1  4 3     RTEMP 20E-3
CGS 1 2     160E-12
DBD 2 4     DBD
**************************************************************** 
.MODEL  NMOS       NMOS ( LEVEL  = 3            TOX    = 5E-8
+ RS     = 30E-3          RD     = 0            NSUB   = 3.62E17  
+ KP     = 2.3E-5         UO     = 650             
+ VMAX   = 0              XJ     = 5E-7         KAPPA  = 1E-3
+ ETA    = 1E-4           TPG    = 1  
+ IS     = 0              LD     = 0               
+ CGSO   = 0              CGDO   = 0            CGBO   = 0 
+ NFS    = 0.8E12         DELTA  = 0.1)
**************************************************************** 
.MODEL  PMOS       PMOS ( LEVEL  = 3            TOX    = 5E-8
+NSUB    = 7E16           TPG    = -1)   
**************************************************************** 
.MODEL DBD D (CJO=55E-12 VJ=0.38 M=0.28
+RS=0.1 FC=0.5 IS=1E-12 TT=5E-8 N=1 BV=30.5)
**************************************************************** 
.MODEL RTEMP RES (TC1=8E-3 TC2=5.5E-6)
**************************************************************** 
.ENDS