*March 21, 2005
*Doc. ID: 76916, S-50383, Rev. B
*File Name: Si3456BDV_PS.txt and Si3456BDV_PS.lib
.SUBCKT Si3456BDV 4 1 2
M1  3 1 2 2 NMOS W=698305u L=0.25u 
M2  2 1 2 4 PMOS W=698305u L=0.35u 
R1  4 3     RTEMP 11E-3
CGS 1 2     390E-12
DBD 2 4     DBD
**************************************************************** 
.MODEL  NMOS       NMOS ( LEVEL  = 3            TOX    = 5E-8
+ RS     = 12E-3          RD     = 0            NSUB   = 2.67E17  
+ KP     = 1.35E-5        UO     = 650             
+ VMAX   = 0              XJ     = 5E-7         KAPPA  = 1E-1
+ ETA    = 1E-4           TPG    = 1  
+ IS     = 0              LD     = 0               
+ CGSO   = 0              CGDO   = 0            CGBO   = 0 
+ NFS    = 0.8E12         DELTA  = 0.1)
**************************************************************** 
.MODEL  PMOS       PMOS ( LEVEL  = 3            TOX    = 5E-8
+NSUB    = 5E16           TPG    = -1)   
**************************************************************** 
.MODEL DBD D (CJO=200E-12 VJ=0.38 M=0.28
+RS=0.1 FC=0.5 IS=1E-12 TT=5E-8 N=1 BV=30.5)
**************************************************************** 
.MODEL RTEMP RES (TC1=8E-3 TC2=5.5E-6)
**************************************************************** 
.ENDS