*Dec 24, 2012
*ECN S12-3060, Rev. E
*File Name: Si7820DN_PS.txt and Si7820DN_PS.lib
*This document is intended as a SPICE modeling guideline and does not
*constitute a commercial product datasheet. Designers should refer to the
*appropriate datasheet of the same number for guaranteed specification
*limits.
.SUBCKT Si7820DN D G S
M1   3  GX S S NMOS W=1277168u L=0.25u 
M2  S  GX S D PMOS W=1277168u L=0.45u
RG  G  GX   2.3
R1  D  3    RTEMP 150E-3
CGS GX S     480E-12
DBD S  D     DBD
**************************************************************** 
.MODEL  NMOS       NMOS ( LEVEL  = 3            TOX    = 10E-8
+ RS     = 42E-3          RD     = 0            NSUB   = 1.65E17  
+ KP     = 6.2E-6         UO     = 650             
+ VMAX   = 0              XJ     = 5E-7         KAPPA  = 4E-1
+ ETA    = 1E-4           TPG    = 1  
+ IS     = 0              LD     = 0               
+ CGSO   = 0              CGDO   = 0            CGBO   = 0 
+ NFS    = 0.8E12         DELTA  = 0.1)
**************************************************************** 
.MODEL  PMOS       PMOS ( LEVEL  = 3            TOX    = 10E-8
+NSUB    = 1E16           TPG    = -1)   
**************************************************************** 
.MODEL DBD D (CJO=170E-12 VJ=0.38 M=0.36
+RS=0.1 FC=0.5 IS=1E-12 TT=5E-8 N=1 BV=202)
**************************************************************** 
.MODEL RTEMP RES (TC1=9.5E-3 TC2=5.5E-6)
**************************************************************** 
.ENDS