*April 10, 2006
*Doc. ID: 77181, S-60543, Rev. B
*This document is intended as a SPICE modeling guideline and does not
*constitute a commercial product data sheet.  Designers should refer to the
*appropriate data sheet of the same number for guaranteed specification
*limits.
.SUBCKT SUM18N25-165 4 1 2
M1  3 1 2 2 NMOS W=3977699u L=0.25u       
M2  2 1 2 4 PMOS W=3977699u L=0.70u   
R1  4 3     RTEMP 52E-3
CGS 1 2     1200E-12
DBD 2 4     DBD
*************************************************************** 
.MODEL  NMOS       NMOS  ( LEVEL  = 3          TOX    = 10E-8
+ RS     = 59E-3           RD     = 0          NSUB   = 1.3E17  
+ KP     = 2E-6            UO     = 650             
+ VMAX   = 0               XJ     = 5E-7       KAPPA  = 3E-2
+ ETA    = 1E-4            TPG    = 1  
+ IS     = 0               LD     = 0                             
+ CGSO   = 0               CGDO   = 0          CGBO   = 0 
+ TLEV   = 1               BEX    = -1.5       TCV    = 9E-3
+ NFS    = 0.8E12          DELTA  = 0.1)
***************************************************************  
.MODEL  PMOS       PMOS  ( LEVEL  = 3          TOX    = 10E-8
+NSUB    = 3E15            TPG    = -1)           
 ************************************************************** 
.MODEL DBD D (CJO=260E-12 VJ=0.38 M=0.38
+RS=1 FC=0.1 IS=1E-12 TT=5E-8 N=1 BV=202)
*************************************************************** 
.MODEL RTEMP R (TC1=14E-3 TC2=5.5E-6)
***************************************************************  
.ENDS