*Jan 23, 2006
*Doc. ID: 77231, S-60073, Rev. B
*File Name: Si8901EDB_PS.txt and Si8901EDB_PS.lib
.SUBCKT Si8901EDB 4 1 2
M1   3 5 2 2 PMOS W=2535426u L=0.25u           
*M2  2 5 2 4 NMOS W=2535426u L=0.40u
R1   4 3     RTEMP 19E-3
CGS  5 2     10000E-12
DBD  4 2     DBD
xesd 1 5 2   Si8901EDB_ESD
***************************************************************  
.MODEL  PMOS       PMOS  ( LEVEL  = 3           TOX    = 1.7E-8
+ RS     = 20E-3           RD     = 0           NSUB   = 1.3E16
+ KP     = 3.4E-6          UO     = 400             
+ VMAX   = 0               XJ     = 5E-7        KAPPA  = 2E-3
+ ETA    = 1E-4            TPG    = -1  
+ IS     = 0               LD     = 0                        
+ CGSO   = 0               CGDO   = 0           CGBO   = 0 
+ NFS    = 0.8E12          DELTA  = 0.1)
*************************************************************** 
.MODEL  NMOS       NMOS  ( LEVEL  = 3           TOX    = 1.7E-8
+NSUB    = 1E17            TPG    = -1)   
*************************************************************** 
.MODEL DBD D (CJO=2400E-12 VJ=0.38 M=0.28
+RS=0.1 FC=0.5 IS=1E-12 TT=6E-8 N=1 BV=20.2)
*************************************************************** 
.MODEL RTEMP RES (TC1=6E-3 TC2=5.5E-6)
*************************************************************** 
.ENDS Si8901EDB
.subckt Si8901EDB_esd 1 5 2
rd7 2 9 4k $TC=0
d7  9 1 dleak  
.MODEL dleak d (IS=5.2e-9 XTI=308 EG=1.17 T_MEASURED=25 TBV1=0 N=33 BV=6.4) 
rd3 2 10 99 TC=-0.002
d3 11 10 dout 1.422
d4 11 12 dout 1.422
d5 13 12 dout 1.78
d6 13 1  dout 1.78
.MODEL dout D (IS=1E-10 XTI=-35 EG=1.17 T_MEASURED=25 TBV1=-8.26e-4 N=2.05 BV=6.05)
rpoly 1 5 5.4K TC=0.001
rd8 2 14 1.3K 
d8 15 14 din  
d9 15 5  din  
.MODEL din D (IS=1E-10 XTI=-20 EG=1.17 T_MEASURED=25 TBV1=-3.39e-4 N=2.5 BV=5.9)
.ends Si8901EDB_esd
 
*This document is intended as a SPICE modeling guideline and does not
*constitute a commercial product data sheet.  Designers should refer to the
*appropriate data sheet of the same number for guaranteed specification
*limits.