*Jan 23, 2006
*Doc. ID: 77237, S-60075, Rev. B
*File Name: Si8902EDB_PS.txt and Si8902EDB_PS.lib
.SUBCKT Si8902EDB 4 1 2
M1   3 5 2 2 NMOS W=3234400u L=0.50u 
*M2  2 5 2 4 PMOS W=3234400u L=0.35u 
R1   4 3     RTEMP 24E-3
CGS  5 2     2300E-12
DBD  2 4     DBD
xesd 1 5 2   Si8902EDB_ESD
************************************************************  
.MODEL  NMOS        NMOS ( LEVEL  = 3        TOX    = 1.7E-8
+ RS     = 7E-3            RD     = 0        NSUB   = 1.8E17  
+ KP     = 6E-6            UO     = 650             
+ VMAX   = 0               XJ     = 5E-7     KAPPA  = 12E-1
+ ETA    = 1E-4            TPG    = 1  
+ IS     = 0               LD     = 0                             
+ CGSO   = 0               CGDO   = 0        CGBO   = 0 
+ NFS    = 0.8E12          DELTA  = 0.1)
************************************************************  
*.MODEL  PMOS       PMOS ( LEVEL  = 3        TOX    = 1.7E-8
*+NSUB    = 2E17           TPG    = -1)   
************************************************************  
.MODEL DBD D (CJO=3900E-12 VJ=0.38 M=0.30
+RS=0.01 FC=0.1 IS=1E-12 TT=5.8E-8 N=1 BV=12.2)
************************************************************ 
.MODEL RTEMP RES (TC1=4E-3 TC2=5.5E-6)
************************************************************  
.ENDS Si8902EDB
.subckt Si8902EDB_esd 1 5 2
rleak 1 9 78850 
dleak 9 2 dleak
.MODEL dleak d (IS=2.69e-9 XTI=404.9 EG=1.17 T_MEASURED=25 TBV1=0 N=31.76 BV=50) 
rout 1 10 21.4
d3 11 10 dout 65.7
d4 11 12 dout 65.7
d5 13 12 dout 69.3
d6 13 2  dout 69.3
.MODEL dout D (IS=1e-11 XTI=-35 EG=1.17 T_MEASURED=25 TBV1=-1.27e-3 N=3 BV=5.885)
rpoly 1 5 3944 TC=0.001
rd8 5 14 1 
d8 15 14 din 34.9
d9 15 2  din 34.9
.MODEL din D (IS=1e-11 XTI=-21.45 EG=1.17 T_MEASURED=25 TBV1=-1.63e-4 N=1.896 BV=6.118)
.ends Si8902EDB_esd
 
*This document is intended as a SPICE modeling guideline and does not
*constitute a commercial product data sheet.  Designers should refer to the
*appropriate data sheet of the same number for guaranteed specification
*limits.