*Jan 23, 2006
*Doc. ID: 77253, S-60073, Rev. B
.SUBCKT Si8900EDB 4 1 2
M1   3 5 2 2 NMOS W=4999800u L=0.50u 
*M2  2 5 2 4 PMOS W=4999800u L=0.35u 
R1   4 3     RTEMP 1.4E-3
CGS  5 2     2300E-12
DBD  2 4     DBD
xesd 1 5 2   Si8900EDB_esd
************************************************************  
.MODEL  NMOS         NMOS (LEVEL  = 3        TOX    = 1.7E-8
+ RS     = 0.56E-3         RD     = 0        NSUB   = 2.13E17  
+ KP     = 6E-5            UO     = 650             
+ VMAX   = 0               XJ     = 5E-7     KAPPA  = 10E-2
+ ETA    = 1E-4            TPG    = 1  
+ IS     = 0               LD     = 0                             
+ CGSO   = 0               CGDO   = 0        CGBO   = 0 
+ TLEV   = 1               BEX    = -1.5     TCV    = 1.7E-3
+ NFS    = 0.8E12          DELTA  = 0.1)
************************************************************  
*.MODEL  PMOS        PMOS (LEVEL  = 3        TOX    = 1.7E-8
*+NSUB    = 2E17           TPG    = -1)   
************************************************************  
.MODEL DBD D (CJO=3900E-12 VJ=0.38  M=0.30
+RS=0.01 FC=0.1 IS=1E-12 TT=5.8E-8 N=1 BV=12.2)
************************************************************ 
.MODEL RTEMP R (TC1=5E-3  TC2=5.5E-6)
************************************************************  
.ENDS Si8900EDB
.subckt Si8900EDB_esd 1 5 2 
rleak 1 9 18950 $TC=0
dleak 9 2 dleak M=1 
.MODEL dleak d (IS=4.763e-9 XTI=376.3 EG=1.17 TREF=25 TCV=0 N=34.89 BV=50) 
rout 1 10 53.7 TC=-1.579e-3
d3 11 10 dout M=1.422
d4 11 12 dout M=1.422
d5 13 12 dout M=1.76
d6 13 2  dout M=1.76
.MODEL dout D (IS=5e-11 XTI=-27.4 EG=1.17 TREF=25 TCV=3.363e-3 N=1.849 BV=5.991)
rpoly 1 5 4113 TC=9.258e-4
rd8 5 14 345.9 
d8 15 14 din M=1
d9 15 2  din M=1
.MODEL din D (IS=5e-11 XTI=-26.83 EG=1.17 TREF=25 TCV=1e-4 N=1.229 BV=6.182)
.ends Si8900EDB_esd 
 
*This document is intended as a SPICE modeling guideline and does not
*constitute a commercial product data sheet.  Designers should refer to the
*appropriate data sheet of the same number for guaranteed specification
*limits.