*Jan 23, 2006
*Doc. ID: 77264, S-60075, Rev. B
*File Name: Si8904EDB_PS.txt and Si8904EDB_PS.lib
.SUBCKT Si8904EDB 4 1 2
M1   3 5 2 2 NMOS W=2708340u L=0.50u 
*M2  2 5 2 4 PMOS W=2708340u L=0.35u 
R1   4 3     RTEMP 20E-3
CGS  5 2     2300E-12
DBD  2 4     DBD
xesd 1 5 2   Si8904EDB_esd
************************************************************  
.MODEL  NMOS         NMOS (LEVEL  = 3        TOX    = 3E-8
+ RS     = 13E-3           RD     = 0        NSUB   = 2E17  
+ KP     = 1.3E-5          UO     = 650             
+ VMAX   = 0               XJ     = 5E-7     KAPPA  = 5E-1
+ ETA    = 1E-4            TPG    = 1  
+ IS     = 0               LD     = 0                             
+ CGSO   = 0               CGDO   = 0        CGBO   = 0 
+ NFS    = 0.8E12          DELTA  = 0.1)
************************************************************  
*.MODEL  PMOS        PMOS (LEVEL  = 3        TOX    = 3E-8
*+NSUB   = 2E17            TPG    = -1)   
************************************************************  
.MODEL DBD D (CJO=3900E-12 VJ=0.38 M=0.30
+RS=0.01 FC=0.1 IS=1E-12 TT=5.8E-8 N=1 BV=30.2)
************************************************************ 
.MODEL RTEMP RES (TC1=8E-3  TC2=5.5E-6)
************************************************************  
.ENDS Si8904EDB
.subckt Si8904EDB_esd 1 5 2
rleak 1 9 238.1k TC=-1.5405e-3
dleak 9 2 dleak   
.MODEL dleak d (IS=3.201e-10 XTI=505.2 EG=1.17 T_MEASURED=25 TBV1=0 N=39.97 BV=50) 
rout 1 10 10.65 TC=-1.122e-3
dout1 10 11 dout 6.37
dout2 11 12 dout 6.72
dout3 2  12 dout 6.37
.MODEL dout D (IS=1e-12 XTI=-8.945 EG=1.17 T_MEASURED=25 TBV1=-9.016e-4 N=3.346 BV=10.19)
rpoly 1 5 1800 TC=1e-3
rd8 5 20 10k TC=4e-3
din1 20 21 dout 3.33
din2 21 22 dout 3.69
din3 2  22 dout 3.33
.ends Si8904EDB_esd 
 
*This document is intended as a SPICE modeling guideline and does not
*constitute a commercial product data sheet.  Designers should refer to the
*appropriate data sheet of the same number for guaranteed specification
*limits.