*March 20, 2006
*Doc. ID: 77270, S-60410, Rev. B
*File Name: SiF912EDZ_PS.txt and SiF912EDZ_PS.lib
*This document is intended as a SPICE modeling guideline and does not
*constitute a commercial product data sheet.  Designers should refer to the
*appropriate data sheet of the same number for guaranteed specification
*limits.
.SUBCKT SiF912EDZ 4 1 2
M1   3 5 2 2 NMOS W=1450483u L=0.25u   
M2   2 5 2 4 PMOS W=1450483u L=0.25u  
R1   4 3     RTEMP 8E-3
CGS  5 2     900E-12
DBD  2 4     DBD
xesd 1 5 2   SiF912EDZ_ESD
************************************************************  
.MODEL  NMOS        NMOS ( LEVEL  = 3        TOX    = 3E-8
+ RS     = 5E-3            RD     = 0        NSUB   = 3.15E17  
+ KP     = 2.5E-5          XJ     = 5E-7     KAPPA  = 5E-2
+ ETA    = 1E-4            TPG    = 1  
+ IS     = 0               LD     = 0                             
+ CGSO   = 0               CGDO   = 0        CGBO   = 0 
+ NFS    = 0.8E12          DELTA  = 0.1)
************************************************************  
.MODEL  PMOS        PMOS ( LEVEL  = 3        TOX    = 3E-8
+NSUB    = 4.3E16          TPG    = -1)   
************************************************************  
.MODEL DBD D (CJO=3900E-12 VJ=0.38 M=0.38
+RS=0.01 FC=0.1 IS=1E-12 TT=5.8E-8 N=1 BV=30.2)
************************************************************ 
.MODEL RTEMP RES (TC1=7E-3 TC2=5.5E-6)
************************************************************  
.ENDS SiF912EDZ
.subckt SiF912EDZ_esd 1 5 2
rleak 1 9 605.7k TC=-4e-3
dleak 9 2 dleak  
.MODEL dleak d (IS=2.043e-9 XTI=654.8 EG=1.17 T_MEASURED=25 TBV1=0 N=51.87 BV=50) 
rout 1 10 43.72 TC=-3.859e-3
dout1 10 11 dout 5.14
dout2 11 12 dout 5.50
dout3 2  12 dout 5.14
.MODEL dout D (IS=7.094e-12 XTI=5.816 EG=1.17 T_MEASURED=25 TBV1=-9.17e-5 N=3.272 BV=10.9)
rpoly 1 5 2300 TC=1e-3
rd8 5 20 1.002 TC=1.706e-3
din1 20 21 dout 2.69
din2 21 22 dout 3.05
din3 2  22 dout 2.69
.ends SiF912EDZ_esd