*Jan 23, 2006
*Doc. ID: 77408, S-60073, Rev. B
*File Name: Si5908DC_PS.txt and Si5908DC_PS.lib
.SUBCKT Si5908DC 4 1 2
M1  3 1 2 2 NMOS W=485249u L=0.50u       
M2  2 1 2 4 PMOS W=485249u L=0.35u  
R1  4 3     RTEMP 14E-3
CGS 1 2     170E-12
DBD 2 4     DBD
**************************************************************************
.MODEL  NMOS        NMOS ( LEVEL  = 3               TOX    = 1.7E-8
+ RS     = 14E-3           RD     = 0		    NSUB   = 2.05E17      
+ KP     = 13E-5           UO     = 650 	
+ VMAX   = 0               XJ     = 5E-7            KAPPA  = 5E-2
+ ETA    = 1E-4            TPG    = 1  
+ IS     = 0               LD     = 0                             
+ CGSO   = 0               CGDO   = 0               CGBO   = 0 
+ NFS    = 0.8E12          DELTA  = 0.1)
*************************************************************************
.MODEL  PMOS        PMOS ( LEVEL  = 3               TOX    = 1.7E-8
+NSUB    = 7E16            TPG    = -1)           
 *********************************************************************
.MODEL DBD D (CJO=150E-12 VJ=0.38 M=0.28
+RS=0.1 FC=0.1 IS=1E-12 TT=5E-8 N=1 BV=20.2)
*************************************************************************
.MODEL RTEMP RES (TC1=6E-3 TC2=5.5E-6)
*************************************************************************
.ENDS        
 
*This document is intended as a SPICE modeling guideline and does not
*constitute a commercial product data sheet.  Designers should refer to the
*appropriate data sheet of the same number for guaranteed specification
*limits.