*Jan 2, 2006
*Doc. ID: 77412, S-52574, Rev. A
*Dn1 Gn1 Sn1 Dn2 Gn2 Sn2
.SUBCKT Si4974DY 8 2 1 6 4 3  
X1    8 2 1 Si4974C1
X2    6 4 3 Si4974C2
.ENDS Si4974DY 
*Channel 1
.SUBCKT Si4974C1 4 1 2
M1  3 1 2 2 NMOS W=1466630u L=0.50u  
M2  2 1 2 4 PMOS W=1466630u L=0.30u 
R1  4 3     RTEMP 7E-3
CGS 1 2     400E-12
DBD 2 4     DBD
****************** ************************************************* 
.MODEL  NMOS        NMOS ( LEVEL  = 3               TOX    = 5E-8
+ RS     = 8E-3            RD     = 0               NSUB   = 2.35E17   
+ kp     = 3E-5            UO     = 650             
+ VMAX   = 0               XJ     = 5E-7            KAPPA  = 5E-1
+ ETA    = 1E-4            TPG    = 1  
+ IS     = 0               LD     = 0                             
+ CGSO   = 0               CGDO   = 0               CGBO   = 0 
+ TLEV   = 1               BEX    = -1.5            TCV    = 3.3E-3
+ NFS    = 0.8E12          DELTA  = 0.1)
******************************************************************** 
.MODEL  PMOS        PMOS ( LEVEL  = 3               TOX    = 5E-8
+NSUB    = 2.6E16          TPG    = -1)   
******************************************************************** 
.MODEL DBD D (CJO=160E-12 VJ=0.38 M=0.16
+FC=0.1 IS=1E-12 TT=5E-8 N=1 BV=30.2)
******************************************************************** 
.MODEL RTEMP R (TC1=7E-3 TC2=5.5E-6)
********************************************************************
.ENDS Si4974C1
*Channel 2
.SUBCKT Si4974C2 4 1 2
M1  3 1 2 2 NMOS W=653317u L=0.50u  
M2  2 1 2 4 PMOS W=653317u L=0.35u 
R1  4 3     RTEMP 14E-3
CGS 1 2     150E-12
DBD 2 4     DBD
****************** ************************************************* 
.MODEL  NMOS        NMOS ( LEVEL  = 3               TOX    = 5E-8
+ RS     = 13E-3           RD     = 0               NSUB   = 2.1E17   
+ kp     = 4E-5            UO     = 650             
+ VMAX   = 0               XJ     = 5E-7            KAPPA  = 10E-1
+ ETA    = 1E-4            TPG    = 1  
+ IS     = 0               LD     = 0                             
+ CGSO   = 0               CGDO   = 0               CGBO   = 0 
+ TLEV   = 1               BEX    = -1.5            TCV    = 3.5E-3
+ NFS    = 0.8E12          DELTA  = 0.1)
******************************************************************** 
.MODEL  PMOS        PMOS ( LEVEL  = 3               TOX    = 5E-8
+NSUB    = 5E16            TPG    = -1)   
******************************************************************** 
.MODEL DBD D (CJO=60E-12 VJ=0.38 M=0.16
+FC=0.1 IS=1E-12 TT=5E-8 N=1 BV=30.2)
******************************************************************** 
.MODEL RTEMP R (TC1=7E-3 TC2=5.5E-6)
******************************************************************** 
.ENDS Si4974C2