*Aug 03, 2009
*Doc. ID: 77417, ECN S09-1458, Rev. D
*File Name: Si4816BDY_PS.txt and Si4816BDY_PS.lib
*This document is intended as a SPICE modeling guideline and does not
*constitute a commercial product data sheet.  Designers should refer to the
*appropriate data sheet of the same number for guaranteed specification
*limits.
.SUBCKT Si4816BDY D1 G1 S1_D2 G2 S2   
X1    D1    G1 S1_D2 Si4816BDYC1
X2    S1_D2 G2 S2    Si4816BDYC2
.ENDS Si4816BDY 
*Channel 1
.SUBCKT Si4816BDYC1 D G S   
M1   3  GX S S NMOS W=1946618u L=0.50u  
M2   S  GX S D PMOS W=1946618u L=0.35u
RG   G  GX     3
R1   D  3      RTEMP 5.5E-3
CGS  GX S      210E-12
DBD  S  D      DBD
****************** ********************************************** 
.MODEL  NMOS        NMOS ( LEVEL  = 3            TOX    = 5E-8
+ RS     = 9E-3            RD     = 0            NSUB   = 1.77E17   
+ kp     = 2.7E-5          UO     = 650             
+ VMAX   = 0               XJ     = 5E-7         KAPPA  = 8E-1
+ ETA    = 1E-4            TPG    = 1  
+ IS     = 0               LD     = 0                           
+ CGSO   = 0               CGDO   = 0            CGBO   = 0 
+ NFS    = 0.8E12          DELTA  = 0.1)
***************************************************************** 
.MODEL  PMOS        PMOS ( LEVEL  = 3            TOX    = 5E-8
+NSUB    = 2E16            TPG    = -1)   
***************************************************************** 
.MODEL DBD D (CJO=300E-12 VJ=0.38 M=0.25 
+FC=0.1 IS=1E-12 TT=5E-8 N=1 BV=75.2)
***************************************************************** 
.MODEL RTEMP RES (TC1=11E-3 TC2=5.5E-6)
***************************************************************** 
.ENDS Si4816BDYC1
*Channel 2
.SUBCKT Si4816BDYC2 D G S 
X1 D G S Si4816BDYC2_MOS
X2 S D  Si4816BDYC2_SCHOTTKY
.ENDS Si4816BDYC2 
.SUBCKT Si4816BDYC2_MOS D G S  
M1   3  GX S S NMOS W=3062590u L=0.50u  
M2   S  GX S D PMOS W=3062590u L=0.35u
RG   G  GX     1.8
R1   D  3      RTEMP 2E-3
CGS  GX S      350E-12
DBD  S D       DBD
****************** ********************************************** 
.MODEL  NMOS        NMOS ( LEVEL  = 3            TOX    = 5E-8
+ RS     = 6E-3            RD     = 0            NSUB   = 2.1E17   
+ kp     = 2E-5            UO     = 650             
+ VMAX   = 0               XJ     = 5E-7         KAPPA  = 4E-1
+ ETA    = 1E-4            TPG    = 1  
+ IS     = 0               LD     = 0                           
+ CGSO   = 0               CGDO   = 0            CGBO   = 0 
+ NFS    = 0.8E12          DELTA  = 0.1)
***************************************************************** 
.MODEL  PMOS        PMOS ( LEVEL  = 3            TOX    = 5E-8
+NSUB    = 2E16            TPG    = -1)   
***************************************************************** 
.MODEL DBD D (CJO=550E-12 VJ=0.38 M=0.25 
+FC=0.1 IS=1E-12 TT=5E-8 N=1 BV=75.2)
***************************************************************** 
.MODEL RTEMP RES (TC1=11E-3 TC2=5.5E-6)
*****************************************************************
.ENDS Si4816BDYC2_MOS
.subckt Si4816BDYC2_SCHOTTKY 7 5 
d1 7 5 sdsm 
d2 7 5 sdlg 
d3 7 4 sdrev 
d4 5 4 sdblk 
.model sdsm d (IS = 1.327e-12 N = 1.100e+00 EG = 1.148e+00 
+XTI = 5.681e+00 RS = 8.959e-03 TRS1 = 3.163e-03 ) 
.model sdlg d (IS = 6.376e-06 N = 1.115e+00 EG = 6.395e-01 
+XTI = 2.092e-03 RS = 1.105e-01 TRS1 = 6.300e-03 
+VJ = 3.092e-01 CJO = 7.511e-10 M = 3.988e-01 
+TT = 1.121e-08 ) 
.model sdrev d (IS = 9.824e-06 N = 1.708e+00 EG = 6.056e-01 
+XTI = 9.361e+00 ) 
.model sdblk d (IS = 1e-11 N=1) 
.ENDS Si4816BDYC2_SCHOTTKY